topic Re: Proc format to create a format from a dataset in SAS Programming

Proc format to create a format from a dataset

NJGIRL — Sun, 25 Jul 2021 22:09:10 GMT

Hi all!

Long time programmer here, however, I am stumped!

Why the heck isn't the format retaining the zeros when I have indicated the format type as 'C'? Here is the code :

data subject(keep=siteid start label fmtname usubjid new_id);

length new_id $12;

set db.en end=end;

new_id = substr(usubjid,8,3) || substr(usubjid,4,3) ;

start = new_id;

label = usubjid;

retain fmtname "SubjectFmt" type "C";

output;

if end then do;

hlo = 'O' ;

label = 'ERROR ;

end;

run;

proc format cntlin = subject cntlout = cntlout; run;

proc format library=work; select SubjectFmt; run;

attached are exampled of the dataset and the resulting format.

Thank you!

NJGirl

Re: Proc format to create a format from a dataset

ChrisNZ — Sun, 25 Jul 2021 22:32:55 GMT

Is usubjid a string?

Re: Proc format to create a format from a dataset

andreas_lds — Mon, 26 Jul 2021 06:39:28 GMT

Please don't hide information in office-files, many contributors won't open such files. Post data as data step using datalines, and attach screenshots using "insert photos" (the small camera icon). And don't forget to post the log as text using "insert code" so that formatting is maintained.

Re: Proc format to create a format from a dataset

FreelanceReinh — Mon, 26 Jul 2021 07:25:46 GMT

@NJGIRL wrote:

Why the heck isn't the format retaining the zeros when I have indicated the format type as 'C'? Here is the code :

data subject(keep=siteid start label fmtname usubjid new_id);

...

Hi @NJGIRL,

Add type to the KEEP= list.

Also add the missing quotation mark in

label = 'ERROR ;

Re: Proc format to create a format from a dataset

NJGIRL — Mon, 26 Jul 2021 13:38:40 GMT

Hi ChrisNZ,

It is a character.

Re: Proc format to create a format from a dataset

Tom — Mon, 26 Jul 2021 14:01:39 GMT

Names of character formats start with $.

Why do you assign a value to TYPE but then drop the variable?

Why do you assign a vlaue to HLO but then drop the variable?
Why do never output the HLO observation?

data subject;
  length fmtname $32 type $1 hlo $3 start new_id $12;
  set db.en end=end;
  new_id = substr(usubjid,8,3) || substr(usubjid,4,3) ;
  start = new_id;
  label = usubjid;
  retain fmtname '$SubjectFmt' type 'C';
  output;
  if end then do;
    hlo = 'O' ;
    label = 'ERROR';
    output;
  end;
  *keep fmtname type start label hlo ;
run;

proc format cntlin = subject cntlout = cntlout; run;

proc format library=work fmtlib; select $SubjectFmt; run;

Re: Proc format to create a format from a dataset

NJGIRL — Mon, 26 Jul 2021 14:44:53 GMT

THANKS SO MUCH TOM. YOU ARE VERY GOOD AT QUICKLY REVIEWING CODE AND SEEING THE OBVIOUS:()

(I guess the answer to your questions would be this: I was staring at it for way too long and couldn't see beyond the weeds. got way too wrapped up it. This happens to me when I stare at code for hours and hours every day!! PHEW.:) 🙂