topic Count words in SAS Programming

Count words

Aexor — Mon, 12 Jul 2021 15:14:25 GMT

Please help me to solve this query:

I have one string as below :

Name = "Is this the real life? Is this just fantasy? Caught in a landslide. No escape from reality!" ;

I need to do these things :-

1. Count the number of words (character strings) separated by blanks in Name1

2. Also I need to get these values too using Name string in a new dataset Name2

Num word

1	Is this the real life
2	Is this just fantasy
3	Caught in a landslide
4	No escape from reality
5

Re: Count words

Tom — Mon, 12 Jul 2021 15:17:50 GMT

Just use COUNTW() function.

data have;
  input num word $60.;
cards;
1 Is this the real life
2 Is this just fantasy
3 Caught in a landslide
4 No escape from reality
5
;

data want;
  set have;
  nwords=countw(word,' ');
run;

Results:

Obs    num             word             nwords

 1      1     Is this the real life        5
 2      2     Is this just fantasy         4
 3      3     Caught in a landslide        4
 4      4     No escape from reality       4
 5      5                                  0

Re: Count words

Aexor — Mon, 12 Jul 2021 15:59:09 GMT

I need to use This string and get values of Num and Word

Name = "Is this the real life? Is this just fantasy? Caught in a landslide. No escape from reality!" ;

Re: Count words

ballardw — Mon, 12 Jul 2021 17:21:09 GMT

@Aexor wrote:
I need to use This string and get values of Num and Word

Name = "Is this the real life? Is this just fantasy? Caught in a landslide. No escape from reality!" ;

How does @Tom 's code not work? Explicit descriptions are needed.

Re: Count words

Aexor — Mon, 12 Jul 2021 17:38:34 GMT

This is not matching with my requirement .
In my requirement I have only a string Name which is having value as "Is this the real life? Is this just fantasy? Caught in a landslide. No escape from reality!" ;
data have ;
Input Name $ ;
Name = "Is this the real life? Is this just fantasy? Caught in a landslide. No escape from reality!" ;
run;
1. The first requirement is Count the number of words (character strings) separated by blanks in new variable Name1

2. The second requirement is
I have to create a dataset (NAME2 ) using dataset have where I can separate out each string delimited with "? or . or ! " and also add sequence number so my output will look like this

data Want
NUM Word
1 Is this the real life
2 Is this just fantasy
3 Caught in a landslide
4 No escape from reality
5

I hope I am making some sense here

Re: Count words

ballardw — Mon, 12 Jul 2021 20:10:08 GMT

First, test data step code. Your input means name will have a total of 8 characters maximum depending on the length of the first "word".

Second, you haven't shown what you expect the FIRST output to actually look like.

data junk;
   Name = "Is this the real life? Is this just fantasy? Caught in a landslide. No escape from reality!" ;
run;

data want1;
   set junk;
   wordcount = countw(name,' ');
run;

data want2;
   set junk;
   do i=1 to countw(name,'.?!');
      word = scan(name,i, '.?!');
      countwd= countw(word);
      output;
   end;
   drop name;
run;

If you need other delimiters such ;:@#$^&* or what have you they can go in the SCAN third position as well.

Re: Count words

Tom — Mon, 12 Jul 2021 20:15:05 GMT

You seem to have skipped the first step. How to you intend to get from your starting data of one long string into your original posted data of four separate strings?

data example;
  paragraph="Is this the real life? Is this just fantasy? Caught in a landslide. No escape from reality!" ;
  do snum=1 to countw(paragraph,'?.!');
    sentence=scan(paragraph,snum,'?.!');
    nwords=countw(sentence,' ');
    output;
  end;
run;