topic Re: How to calculate relative Risk and confidence Interval in SAS Programming

How to calculate relative Risk and confidence Interval

Dhana18 — Fri, 09 Jul 2021 17:59:33 GMT

data MSM2017;
input Alerts $   MSM $  Counts;
Datalines;
No Yes 20
No No 240
Yes Yes 3
Yes No 3
 ;
proc freq data=MSM2017;
tables MSM*Alerts/RELRISK;
WEIGHT COUNTS ;
RUN;

Hi i would like to know what is wrong with the code i have above. There are 3 patients that are MSM and they are Alert, and there are 20 patients that are MSM but they are not alert. There are 3 patients that are Alerts but they are not MSM, and there are 240 patients that are not MSM and Not Alert.

I would like to know what is risk of being MSM to become an Alert. Is MSM at higher risk of becoming an alert patient?

Re: How to calculate relative Risk and confidence Interval

Reeza — Fri, 09 Jul 2021 19:01:34 GMT

What makes you think something is wrong with your code? You have a small event size, so I question the reliability of this analysis but from a purely SAS technical standpoint there's no issue with the code you've shown. It runs without errors for me.

Re: How to calculate relative Risk and confidence Interval

Dhana18 — Fri, 09 Jul 2021 20:33:51 GMT

I may be not interpreting it well. So what is the risk ratio? My colleague got RR of 10.57 using excel

Re: How to calculate relative Risk and confidence Interval

Reeza — Fri, 09 Jul 2021 20:37:39 GMT

So your real question is how to interpret the results from this code?

Re: How to calculate relative Risk and confidence Interval

FreelanceReinh — Mon, 12 Jul 2021 07:34:55 GMT

Hi @Dhana18,

@Dhana18 wrote:
My colleague got RR of 10.57 using excel

That value is correct and you'll obtain it also with SAS (for "Column 2," i.e., Alerts='Yes') if you switch the rows of the 2x2 table, i.e., have MSM='Yes' as the first row, so that the relative risk is the risk ratio of MSM='Yes' vs. MSM='No' and not vice versa (which is what you currently get: 0.09465... = 1/10.5652...). One way to achieve this is to sort the dataset as needed and then use the ORDER=DATA option of the PROC FREQ statement.

proc sort data=MSM2017;
by descending MSM descending Alerts;
run;

proc freq data=MSM2017 order=data;
tables MSM*Alerts/RELRISK;
WEIGHT COUNTS ;
RUN;

Note however, how wide the 95% confidence interval for this relative risk is (due to the small numbers in column 2, as Reeza mentioned).

Edit: If you also want to report the odds ratio, you should switch the columns as well (see extended BY statement above; the relative risk is then reported as that of "Column 1"). Thanks to @Reeza for pointing this out.

Re: How to calculate relative Risk and confidence Interval

Reeza — Sun, 11 Jul 2021 23:15:46 GMT

I don’t believe the Alert column is in the right order though?

Re: How to calculate relative Risk and confidence Interval

FreelanceReinh — Mon, 12 Jul 2021 07:33:54 GMT

Thanks, @Reeza, this is a good point if @Dhana18 plans to report the odds ratio in addition to the relative risk. (The relative risks are computed for both columns, but the odds ratio depends on the order of columns.) I'm going to edit my suggested solution.