topic ERROR: The decimal specification of 15 must be less than the width specification of 15 in SAS Programming

ERROR: The decimal specification of 15 must be less than the width specification of 15

commitsudoku — Fri, 02 Jul 2021 15:03:19 GMT

Hi. I have a CSV file with 5600 rows and 331 columns. I successfully import the data using PROC IMPORT into RESULTS.

Once imported I can visualize the data in SAS and even use PROC FREQ and PROC TABULATE on RESULTS.

But I need to recode some variables and for that I need to use PROC DATA.

So a very simple command just to put my imported data into a DATA PROC.

DATA data;
	SET RESULTS;
RUN;

But this gives the following error:

ERROR: The decimal specification of 15 must be less than the width specification of 15

Why is that?

Thank you,

Re: ERROR: The decimal specification of 15 must be less than the width specification of 15

Kurt_Bremser — Fri, 02 Jul 2021 15:15:32 GMT

Run a PROC CONTENTS to see which variable(s) have the incriminated format, which you can then correct with PROC DATASETS.

Re: ERROR: The decimal specification of 15 must be less than the width specification of 15

Tom — Fri, 02 Jul 2021 15:31:22 GMT

Run PROC CONTENTS on the dataset.

Find the offending format.

proc contents data=results out=contents noprint;
run;

data _null_;
  set contents;
  where formatd >= formatl >0 ;
  put (libname memname name format formatd formatl) (=);
run;

Fix it.

For example why not just remove any formats that PROC IMPORT decided to attach? You normally do not need formats attached to numeric variables (unless they are date, time or datetime values).

DATA data;
   SET RESULTS;
   format _all_;
RUN;

Re: ERROR: The decimal specification of 15 must be less than the width specification of 15

commitsudoku — Tue, 06 Jul 2021 10:39:08 GMT

Thank you so much! It worked perfectly!