topic Re: written out epoch time stamp of UNIX to sas timestamp in SAS Programming

written out epoch time stamp of UNIX to sas timestamp

FK1 — Wed, 16 Jun 2021 15:51:37 GMT

Hi Everyone,

I want to get the "last modified" timestamp of a file residing in a AIX filesytem.

When I use this AIX-command:

istat SASWebReportStudio4.4_KeyActions.log | grep modified |  awk '{print $3, $4, $5,  $6, $7, $8}'

I get this output:

Wed Jun 16 17:35:28 CEST 2021

Can someone tell me, how the heck I can get this into a decent SAS timestamp?

Thx

Re: written out epoch time stamp of UNIX to sas timestamp

Kurt_Bremser — Wed, 16 Jun 2021 16:23:47 GMT

/usr/linux/bin/ls provides a GNU ls with the option --time-style, which allows you to get ISO-compliant timestamps (which you can read with E8601/B8601 infornats).

Re: written out epoch time stamp of UNIX to sas timestamp

FK1 — Thu, 17 Jun 2021 06:49:05 GMT

Good morning @Kurt_Bremser ,

unfortunately, I cannot find the GNU ls version under /usr/linux/bin/ls. Here is, what we have:

Is there any other way?

Re: written out epoch time stamp of UNIX to sas timestamp

Kurt_Bremser — Thu, 17 Jun 2021 07:35:34 GMT

That's unfortunate. Your server admins should install the whole GNU coreutils package, it contains a lot of very useful tools (e.g. /usr/linux/bin/date has a lot of VERY USEFUL options for handling dates in shell scripts).

Use the built-in SAS functions:

data mod_time;
length fref $8;
rc = filename(fref,"/sas/conf/Lev1/Web/Logs/SASServer1_1/SASWebReportStudio4.4.log.2021-06-15");
fid = fopen(fref);
if fid ne 0
then do;
  timestamp = input(finfo(fid,foptname(fid,5)),nldatm.);
  rc = fclose(fid);
end;
rc = filename(fref);
format timestamp e8601dt19.;
run;

You need to use the NLS informat because the FINFO function returns the timestamp in your locale.

Re: written out epoch time stamp of UNIX to sas timestamp

FK1 — Fri, 18 Jun 2021 09:21:44 GMT

@Kurt_Bremser : one follow-up question:

Using your code, I get the filoption number 5 (Last Modified Date) without any seconds, which in turn creates a time stamp assuming that the seconds part is zero:

LastModified timestamp
18. Juni 2021 10.53 Uhr 1939632780
20. Mai 2021 02.31 Uhr 1937097060
22. Mai 2021 02.31 Uhr 1937269860
24. Mai 2021 02.31 Uhr 1937442660
26. Mai 2021 02.31 Uhr 1937615460
30. Mai 2021 02.31 Uhr 1937961060
01. Juni 2021 02.31 Uhr 1938133860
03. Juni 2021 02.31 Uhr 1938306660
05. Juni 2021 22.09 Uhr 1938550140
12. Juni 2021 02.31 Uhr 1939084260
16. Juni 2021 02.31 Uhr 1939429860

Is this due to the formats used? Woulde Do I have to change the widths of the respective formats?

How can I get the sconds part of the last modified date?

When looking at OS level, I can see that the seconds part should be "15", "45", "45", .... .

Re: written out epoch time stamp of UNIX to sas timestamp

Kurt_Bremser — Fri, 18 Jun 2021 14:48:03 GMT

Then we need to go back to the istat output.

Use the SCAN function to get the pieces.

The 3rd, 2nd and 5th concatenated can be INPUT with DATE9., and the 4th INPUT with TIME8. Then combine both with the DHMS function.

Re: written out epoch time stamp of UNIX to sas timestamp

FK1 — Mon, 28 Jun 2021 08:31:55 GMT

Hi @Kurt_Bremser ,

the problem with using the istat-command way is, that you cannot give a wildcard-search for ALL KeyAction Logs ("Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log*"), because the command expects a specific, unique path to ONE file.

Therefore, I will have to iterate through all the KeyActions-Logfiles...

Nevertheless, the command and the transformation of the feedback of istat-command works:

%LET l_cmd = %nrbquote(istat /please/put/your/path/here/config/LevX/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log | grep modified |  awk '{print $3, $4, $5,  $6, $7, $8}');

/*set up pipe*/
filename oscmd pipe "&l_cmd.";

data work.test   ;
infile oscmd truncover;
input string $50. ;

format timestamp datetime25. date date9. time time8.;

date = input(scan(string,3)||scan(string,2)||scan(string,6),date9.);
time = input(scan(string,4), time8.);

timestamp = dhms(date, hour(time), minute(time), second(time));
run;

Re: written out epoch time stamp of UNIX to sas timestamp

Kurt_Bremser — Tue, 29 Jun 2021 07:31:34 GMT

You can do this in one data step by use of the dynamic pipe:

data lognames;
infile datalines truncover;
input logfilepath $255.;
datalines;
/sas/conf/Lev1/Web/Logs/SASServer1_1/SASWebReportStudio4.4_KeyActions.log
;

data work.test;
set lognames;
length command $1000;
command = catx(" ","istat",logfilepath,"| grep modified |  awk '{print $3, $4, $5,  $6, $7, $8}'");
format timestamp datetime25. date date9. time time8.;
infile dummy pipe filevar=command end=done truncover;
do until (done);
  input string $50. ;
  date = input(scan(string,3)||scan(string,2)||scan(string,6),date9.);
  time = input(scan(string,4), time8.);
  timestamp = dhms(date, hour(time), minute(time), second(time));
  output;
end;
run;

Re: written out epoch time stamp of UNIX to sas timestamp

FK1 — Thu, 01 Jul 2021 15:22:44 GMT

@Kurt_Bremser : Very elegant! However, this assumes, that I have to MANUALLY write every Logfilename into the datalines Statement:

data lognames ;
infile datalines truncover;
input logfilepath $255.;
datalines;
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210601_023145
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210603_023144
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210605_220912
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210612_023145
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210616_023148
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210619_023144
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210622_023142
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210624_023144
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210627_023144
/sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/SASWebReportStudio4.4_KeyActions.log_20210701_023144
;

Is there a way to AUTOMATICALLY let sas "fill in" the dataline lines? Maybe somehow with call execute?

So far, I can generate a dataset that list all the Logfiles:

%LET KeyActionPath = /sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/;
%LET KeyActionLogname = SASWebReportStudio4.4_KeyActions.log;
%LET ls_cmd = %nrbquote(ls -l &KeyActionPath.&KeyActionLogname.* |  awk '{ print $9 }');

/*set up pipe*/
filename oscmd pipe "&ls_cmd.";

data work.Liste_KeyactionLogs   ;
infile oscmd truncover;
input  logfilepath $255.  ;
run;

filename oscmd clear;

Voila:

But how can I "plug in" this list into the datalines statement?

Re: written out epoch time stamp of UNIX to sas timestamp

Kurt_Bremser — Thu, 01 Jul 2021 17:26:39 GMT

You already have it! Your dataset is the same as my lognames dataset, just use it in the data step with the dynamic pipe.

Re: written out epoch time stamp of UNIX to sas timestamp

FK1 — Thu, 01 Jul 2021 20:23:40 GMT

@Kurt_Bremser : of course! Vor lauter Bäumen den Wald nicht gesehen!

Here is the complete (dense) code:

%LET KeyActionPath = /sas_install_web_p/config/Lev3/Web/Logs/SASServer2_1/;
%LET KeyActionLogname = SASWebReportStudio4.4_KeyActions.log;
%LET ls_cmd = %nrbquote(ls -l &KeyActionPath.&KeyActionLogname.* |  awk '{ print $9 }');

/*set up pipe*/
filename oscmd pipe "&ls_cmd.";

data work.KeyactionLogs_mit_ZS (keep=logfilepath timestamp);
infile oscmd truncover;
input  logfilepath $255.  ;
length command $1000;
command = catx(" ","istat",logfilepath,"| grep modified |  awk '{print $3, $4, $5,  $6, $7, $8}'");
format timestamp datetime25. date date9. time time8.;
infile dummy pipe filevar=command end=done truncover;
do until (done);
  input string $50. ;
  date = input(scan(string,3)||scan(string,2)||scan(string,6),date9.);
  time = input(scan(string,4), time8.);
  timestamp = dhms(date, hour(time), minute(time), second(time));
  output;
end;
run;

filename oscmd clear;

Thank you, Kurt!