topic Observation in SAS Programming

Observation

Sowmya12 — Mon, 14 Jun 2021 12:30:17 GMT

If visit contains screening and day1 as
subjid visit
1 101 screening
2 101 day 1
Those visits are present as 2 observations
I need the output as
Subjid visit
101 screening/day-1

Re: Observation

PaigeMiller — Mon, 14 Jun 2021 12:41:40 GMT

It's really difficult to generalize from data with only one ID. Are there always two records for each ID? Are there ever one or three records for each ID? What do we do in those cases? Are the records for ID consecutive and in the proper order?

Re: Observation

tarheel13 — Mon, 14 Jun 2021 13:43:42 GMT

Can you please post some sample data as datalines? What is the dataset you want? 1 row per subjid?

Re: Observation

Sowmya12 — Mon, 14 Jun 2021 13:55:24 GMT

There are 2 records for every id

101 screening
101 day-1
102 screening
102 day-1
103 screening
103 day-1

Can we get this kind of output as below

101 screening/day-1
102 screening/day-1
103 screening/day-1

Re: Observation

PaigeMiller — Mon, 14 Jun 2021 14:08:56 GMT

Please try to give us meaningful examples that cover a number of realistic outcomes, instead of one possible outcome.

Is the end result always the ID followed by the exact unchanging text "screening/day-1"? Or are there other possible text strings that might appear? Give us a realistic example.

Re: Observation

tarheel13 — Mon, 14 Jun 2021 14:07:54 GMT

You need to transpose it and then concatenate the columns.

data example;
length visit $ 25;
input subjid visit $ ;
datalines;
101 screening
101 day-1
102 screening
102 day-1
103 screening
103 day-1
;
run;

proc sort data=example;
	by subjid;
run;

proc transpose data=example out=example_t(drop=_name_);
	by subjid;
	var visit;
run;

data example_t2;
	set example_t;
	visit=strip(col1)||'/'||strip(col2);
	drop col1 col2;
run;

Re: Observation

Sowmya12 — Mon, 14 Jun 2021 14:17:24 GMT

Yes that is the exact output with same id

Re: Observation

tarheel13 — Mon, 14 Jun 2021 14:22:45 GMT

I gave you a solution that gets your desired output.

Re: Observation

Sowmya12 — Mon, 14 Jun 2021 14:25:24 GMT

Thanku for the solution and sorry for problem regarding the question.

Thanks
Sowmya

Re: Observation

PaigeMiller — Mon, 14 Jun 2021 14:31:09 GMT

@Sowmya12 wrote:
Yes that is the exact output with same id

data want;
     set have;
     by subjid visit;
     if first.visit then text="screening/day-1";
    else delete;
run;

Re: Observation

Ksharp — Tue, 15 Jun 2021 12:32:30 GMT

data have;
input subjid visit : $20.;
cards;
101 screening
101 day-1
102 screening
102 day-1
103 screening
103 day-1
;
data want;
 do until(last.subjid);
  set have;
  by subjid;
  length want $ 80;
  want=catx('/',want,visit);
 end;
 drop visit;
 run;