topic Re: SAS BASE in SAS Programming

SAS BASE

u58780790 — Fri, 11 Jun 2021 10:48:13 GMT

Read sample input of 5 rows & 3 columns (name , Gender, Age) using data lines into a temporary SAS dataset, and create new column Age-group with values ( >45, 18-44, 0-5,5-11,11-18 ) while reading the datalines into SAS datasets.

Based on age column,

Create a new column Age group

Based a=on age value derive age group below is example for Age value and corresponding age group value.

Age Agegroup

5 0-5

65 >45

90 >45

30 18-44

SOLUTION:

data task;
input name $ gender $ age;
datalines;
Reena F 25
Shyam M 40
Deva M 53
John M 63
Mery F 9
;
a=age;
if 0<a<=5 then agegroup=0-5;
if 5<a<=11 then agegroup=5-11;
if 11<a<=18 then agegroup =11-18;
if 18<a<=44 then agegroup=18-44;
if a>45 then agegroup=>45;
run;

I have tried in this way but its not coming. please help me out......

Re: SAS BASE

ChrisNZ — Fri, 11 Jun 2021 10:48:46 GMT

Surely your teacher and course material showed you how to do this.

What have you tried?

Re: SAS BASE

u58780790 — Fri, 11 Jun 2021 10:56:24 GMT

Hii

No I tried!... One line logic is not getting! Help me out

Re: SAS BASE

andreas_lds — Fri, 11 Jun 2021 11:04:19 GMT

Please

change the title so that it is in closer connection to the problem you have,
use the "insert sas code" button to insert properly formatted code,
show what you have tried so far.

I would use proc format to define a format, to avoid if-then-else, and then, after the input-statement, the input-function:

agegroup = input(Age, AgeGroupFmt.);

Re: SAS BASE

u58780790 — Fri, 11 Jun 2021 11:08:03 GMT

data sample;
input name $ gender $ age;
datalines;
Vinod M 10
Shalini F 18
Reena F 25
Rishi M 40
Sampath M 55
;
a=age
aggrp=put(a,agegroup.);
run;

proc format;
value agegroup
0-5='0-5'
5-11='5-11'
11-18='11-18'
18-44='18-44'
>45='>45';
run;

Re: SAS BASE

Astounding — Fri, 11 Jun 2021 12:11:14 GMT

You have some nearly working pieces. Let's change a few things.

First, to use a format you have to first create it. So PROC FORMAT must be moved to before the DATA step.

Second, there is a syntax error in the PROC FORMAT. The way to get 45 and higher in the same group is to specify:

45 - high = '>45';

Third, expect that the first mention of a number determines which group it belongs to. So 5 will go into the "0-5" category, not into the "5-11" category.

Fourth, there is no need to create the variable A. You have AGE, and can use it:

aggrp=put(age, agegroup.);

Re: SAS BASE

u58780790 — Fri, 11 Jun 2021 12:27:17 GMT

proc format;
value agegroup
0-5='0-5'
6-11='5-11'
12-18='11-18'
19-44='18-44'
45-high='>45';
run;

data sample;
input name $ gender $ age;
datalines;
Vinod M 10
Shalini F 18
Reena F 25
Rishi M 40
Sam M 55
;
aggrp=input(age,agegroup.);
run;

Is this right ?
But it doesn't give the output... shows error at aggrp line....

Re: SAS BASE

tarheel13 — Fri, 11 Jun 2021 12:28:12 GMT

Those formats are not going to work the way you've written them. Please try my code.


proc format;
	value agegroupf
	1='0-5'
	2='5-11'
	3='11-18'
	4='18-44'
	5='>45';
run;

 data task2;
 	set task;
	format agegroup agegroupf.;
	if age > .z then do;
	if age lt 5 then agegroup=1;
	else if 5 le age lt 11 then agegroup=2;
	else if 11 le age lt 18 then agegroup=3;
	else if 18 le age lt 45 then agegroup=4;
	else if age ge 45 then agegroup=5;
		end;
run;

title "Check agegroup derivation";
proc means data=task2 n nmiss min max;
	var age;
	class agegroup / missing;
run;
title;

Re: SAS BASE

Astounding — Fri, 11 Jun 2021 12:30:25 GMT

You switched the PUT function to the INPUT function. Restore the PUT function.

Re: SAS BASE

u58780790 — Fri, 11 Jun 2021 12:36:05 GMT

if age > .z then do;

can u explain y this comes?

Re: SAS BASE

tarheel13 — Fri, 11 Jun 2021 12:41:43 GMT

Well, I put it there to only include non-missing age values.

Re: SAS BASE

tarheel13 — Fri, 11 Jun 2021 12:52:32 GMT

You're still going to get errors with the code like that. You need to move aggrp before datalines statement but I also think your ranges in proc format are not good. What if someone has an age between 5 and 6 or between 11 and 12? All of those people are going to get left out with the way you've assigned the ranges. Please read the documentation.

https://documentation.sas.com/doc/en/vdmmlcdc/8.1/proc/n03qskwoints2an1ispy57plwrn9.htm

Also, it is ALWAYS a good idea to check your work. Please run the proc means that I use to check the derivation of aggrp.

proc format;
value agegroup
0-5='0-5'
6-11='5-11'
12-18='11-18'
19-44='18-44'
45-high='>45';
run;


data sample;
	infile datalines;
	input name $ gender $ age;
	aggrp=put(age,agegroup.);
	datalines;
Vinod M 10
Shalini F 18
Reena F 25
Rishi M 40
Sam M 55
;
proc print data=sample;
run;

proc means data=sample n nmiss min max;	
	var age;
	class agegroup / missing;
run;

Re: SAS BASE

Kurt_Bremser — Fri, 11 Jun 2021 13:34:16 GMT

@u58780790 wrote:
proc format;
value agegroup
0-5='0-5'
6-11='5-11'
12-18='11-18'
19-44='18-44'
45-high='>45';
run;

data sample;
input name $ gender $ age;
datalines;
Vinod M 10
Shalini F 18
Reena F 25
Rishi M 40
Sam M 55
;
aggrp=input(age,agegroup.);
run;

Is this right ?
But it doesn't give the output... shows error at aggrp line....

The crucial point is the DATALINES statement, which is documented here; you will find the clue in there.

Re: SAS BASE

u58780790 — Fri, 11 Jun 2021 13:45:33 GMT

can it be done in datastep without proc format?

Re: SAS BASE

tarheel13 — Fri, 11 Jun 2021 13:51:29 GMT

I have shown a data step solution. If you don't want to do agegroup=1,2,3,4,5 and apply a format then just set agegroup = '0-5', '5-11' and so on and so forth.

Re: SAS BASE

Astounding — Fri, 11 Jun 2021 14:17:33 GMT

One last response, modifying your latest program slightly:

proc format;
value agegroup
0-5='0-5'
6-11='5-11'
12-18='11-18'
19-44='18-44'
45-high='>45';
run;

data sample;
input name $ gender $ age;
aggrp = put(age, agegroup.);
datalines;
Vinod M 10
Shalini F 18
Reena F 25
Rishi M 40
Sam M 55
;

Once a semicolon marks the end of the datalines, you no longer need a run statement.

Re: SAS BASE

Reeza — Fri, 11 Jun 2021 15:17:36 GMT

You missed a few concepts with your initial code:

No code after datalines is executed. You needed to move your IF statements BEFORE your datalines/cards statements.
Use IF/ELSE IF, not multiple IF statements
AgeGroup values need to be in quotation marks as it's a character variable.
Set a length for AgeGroup ahead of time so that the value isn't truncated.

Example is here.

data task;
input name $ gender $ age;
a=age;

length agegroup $10.;

if 0<a<=5 then agegroup="0-5";
else if 5<a<=11 then agegroup="5-11";
else if 11<a<=18 then agegroup ="11-18";
else if 18<a<=44 then agegroup="18-44";
else if a>45 then agegroup= ">45";

datalines;
Reena F 25
Shyam M 40
Deva M 53
John M 63
Mery F 9
;
run;

@u58780790 wrote:

Read sample input of 5 rows & 3 columns (name , Gender, Age) using data lines into a temporary SAS dataset, and create new column Age-group with values ( >45, 18-44, 0-5,5-11,11-18 ) while reading the datalines into SAS datasets.

Based on age column,

Create a new column Age group

Based a=on age value derive age group below is example for Age value and corresponding age group value.

Age Agegroup

5       0-5

65    >45

90   >45

30   18-44

SOLUTION:

data task;
input name $ gender $ age;
datalines;
Reena F 25
Shyam M 40
Deva M 53
John M 63
Mery F 9
;
a=age;
if 0<a<=5 then agegroup=0-5;
if 5<a<=11 then agegroup=5-11;
if 11<a<=18 then agegroup =11-18;
if 18<a<=44 then agegroup=18-44;
if a>45 then agegroup=>45;
run;

I have tried in this way but its not coming. please help me out......

Re: SAS BASE

u58780790 — Fri, 11 Jun 2021 15:22:10 GMT

where the datastep solution has? can u show me?

Re: SAS BASE

tarheel13 — Fri, 11 Jun 2021 15:33:48 GMT

Would you please look at what @Reeza just posted? A lot of people have given you solutions now.

Re: SAS BASE

u58780790 — Fri, 11 Jun 2021 15:35:57 GMT

yup i am seeing that
thank u !