topic Re: replacing values with yes or no in SAS Programming

replacing values with yes or no

Solly7 — Wed, 09 Jun 2021 07:25:02 GMT

Hi i need help in replacing the values from below code with yes or no....if the value = I don't drink alcohol then replace it with no, otherwise replace it with yes..

data have;
input policy_no Alcohol & $80.;
datalines;
1 I don't drink alcohol
2 Less than 5 drinks
3 Between 5 and 21 drinks
;

Re: replacing values with yes or no

Astounding — Wed, 09 Jun 2021 07:42:25 GMT

Replacing it is a bad idea. You actually lose information. Instead, create a new variable. One way:

data want;
   set have;
   length alcohol_yn $ 3;
   if alcohol = "I don't drink alcohol" then alcohol_yn = "no";
   else if alcohol > " " then alcohol_yn = "yes";
run;

Notice that the new variable will be left blank if the original variable is blank. Also note that comparisons require an exact match ... spelling, capitalization, punctuation.

Re: replacing values with yes or no

DavePrinsloo — Wed, 09 Jun 2021 08:26:06 GMT

You may want to test on policy_no:. I assume you will be getting data from elsewhere, so you probably need to handle the case where no reply is given.

data have;
input policy_no Alcohol & $80.;

if policy_no = . then alcohol = 'unknown';
else if policy_no = 1 then alcohol = 'no';
else alcohol = 'yes';

datalines;
1 I don't drink alcohol
2 Less than 5 drinks
3 Between 5 and 21 drinks
;

Re: replacing values with yes or no

andreas_lds — Wed, 09 Jun 2021 09:44:28 GMT

If you wan a new variable, using an informat seems to be a good idea:

proc format;
	invalue $alcoIn (upcase)
		' ' = ' '
		"I DON'T DRINK ALCOHOL" = 'no'
		other = 'yes'
	;	
run;

data want;
	set have;
	length alcohol_yn $3;
	
	alcohol_yn = input(alcohol, $alcoIn.);
run;