topic Re: Assign random date in SAS Programming

Assign random date

di_niu0 — Fri, 04 Jun 2021 16:08:48 GMT

Hi All,

I would like to assign a random date for each observation. There are two conditions to fulfill.

1. The assign date has to be between Jan 1, 2015 and Dec 31, 2015.

2. The assign date has to be after each observation's start date.

ID Start_Date

1 01JAN2015

2 01JUN2015

3 31DEC2015

Thank you!

Re: Assign random date

di_niu0 — Fri, 04 Jun 2021 16:13:41 GMT

For ID 3, the assign date is Dec 31, 2015.

Re: Assign random date

Tom — Fri, 04 Jun 2021 16:22:46 GMT

Use the RAND() function with 'INTEGER' type.

data have ;
  input id Start_Date :date.;
  format start_date date9.;
cards;
1              01JAN2015
2              01JUN2015
3              31DEC2015
;

data want;
  set have;
  stop_date = rand('integer',max(start_date,"01JAN2015"d),"31DEC2015"d);
  format stop_date date9.;
run;

proc print;
run;

Results:

               Start_
Obs    id         Date    stop_date

 1      1    01JAN2015    05OCT2015
 2      2    01JUN2015    10AUG2015
 3      3    31DEC2015    31DEC2015

Re: Assign random date

Kurt_Bremser — Fri, 04 Jun 2021 16:23:31 GMT

Use the RAND function with the INTEGER distribution:

data have;
input ID $ Start_Date :date9.;
format start_date yymmdd10.;
datalines;             
1              01JAN2015
2              01JUN2015
3              31DEC2015
;

data want;
set have;
assign_date = rand('integer',max(start_date,'01jan2015'd),'31dec2015'd);
format assign_date yymmdd10.;
run;

Re: Assign random date

PaigeMiller — Fri, 04 Jun 2021 16:26:05 GMT

data have; 
input ID Start_Date :date9.;   
cards; 
1              01JAN2015
2              01JUN2015
3              31DEC2015
;

data want;
    set have;
    end_date='31DEC2015'd;
    number_of_days_start_to_end=end_date-start_date+1;
    random_date=start_date+rand('integer',0,number_of_days_start_to_end);
    format random_date date9.;
run;

Re: Assign random date

di_niu0 — Fri, 04 Jun 2021 17:06:49 GMT

That works well. Thank you!

Re: Assign random date

di_niu0 — Fri, 04 Jun 2021 17:07:21 GMT

Thank you!

Re: Assign random date

di_niu0 — Fri, 04 Jun 2021 17:07:44 GMT

Thank you!