topic Re: why the number of year and month is added 1 when remove the 'output'? in SAS Programming

why the number of year and month is added 1 when remove the 'output'?

tianerhu — Tue, 18 May 2021 02:23:38 GMT

libname results 'C:\practice everyday\output';
data results.output13_2;
total = 100;
do year = 1 to 3;
  do month = 1 to 12;
   total + total*0.05;
 output;
 end;
 total + 50;
end;
run;
proc print data = results.output13_2;
run;

libname results 'C:\practice everyday\output';
data results.output13_2;
total = 100;
do year = 1 to 3;
do month = 1 to 12;
total + total*0.05;
*output;
end;
total + 50;
end;
run;
proc print data = results.output13_2;
run;

Re: why the number of year and month is added 1 when remove the 'output'?

mkeintz — Tue, 18 May 2021 03:13:44 GMT

In your first program you have an explicit OUTPUT statement inside the DO loop. Therefore the normal implicit OUTPUT (just before the RUN; statement) is eliminated. But in your second program, there is no explicit OUTPUT, so the implicit OUTPUT is executed.

So the question really is "why does the iterator YEAR in DO YEAR=1 to 3; ... END; end up as a 4"? The iterator is always incremented (from 1 to 2, 2 to 3, 3 to 4) at the end of each iteration.. Once YEAR=4 there is no subsequent iteration of the DO loop executed, because it is now outside of the upper limit of 3. Here's code to show that:

data _null_;
  do year=1 to 3 ;
    put 'inside ' year=;
  end;
  put 'after  ' year=;
run;

Now, if you really want to iterate from year=1 to 3 without year being incremented to 4 you can add an UNTIL expression:

data _null_;
  do year=1 to 3 until (year=3);
    put 'inside ' year=;
  end;
  put 'after  ' year=;
run;

This works because the UNTIL expression (telling the loop when to stop) is evaluated at the end of each iteration, but before the iterator is incremented.

Re: why the number of year and month is added 1 when remove the 'output'?

tianerhu — Tue, 18 May 2021 11:17:12 GMT

Thank you so much .

Re: why the number of year and month is added 1 when remove the 'output'?

tianerhu — Tue, 18 May 2021 11:35:03 GMT

Could you explain why the variable month become 13, the same way to the variable year ?

Re: why the number of year and month is added 1 when remove the 'output'?

PaigeMiller — Tue, 18 May 2021 11:39:29 GMT

@tianerhu wrote:

Could you explain why the variable month become 13, the same way to the variable year ?

It's the same reason as year; the loop increments month to 13, then it stops as the loop will not run when month is 13.

Re: why the number of year and month is added 1 when remove the 'output'?

tianerhu — Tue, 18 May 2021 12:44:37 GMT

Thank you for your help.