topic Re: Add Leading zero max of 10 in SAS Programming

Add Leading zero max of 10

Q1983 — Wed, 12 May 2021 16:05:07 GMT

data have;
length
  loan_number $10
  
;
input loan_number ;

datalines;
2323333
22345099
112009899
345566
;
run;

data have2;
set have;
ln_no=put(loan_number,z10.);
run;

I ran the code and received format not found.  Note this is a character variable.  I want to assign leading zeros as needed to get a max 10 digit number in character format

Re: Add Leading zero max of 10

Reeza — Wed, 12 May 2021 16:19:16 GMT

Your original variable needs to be numeric. Convert it to a number and then apply the Z format.

ln_no = put( input(Loan_number, best12.), z10.);

Re: Add Leading zero max of 10

AMSAS — Wed, 12 May 2021 16:24:36 GMT

In SAS there's always another way / different approach:

data have;
	length
  		loan_number $10 ;
	input loan_number ;
	loan_number=substr("0000000000"||loan_number,length(loan_number)) ;

datalines;
2323333
22345099
112009899
345566
;
run;

Re: Add Leading zero max of 10

Reeza — Wed, 12 May 2021 16:31:17 GMT

Most definitely....I think there's at least two other ways to solve this I can think about, one using REPEAT() and another using SUBSTR() as well.

Re: Add Leading zero max of 10

Tom — Wed, 12 May 2021 16:31:32 GMT

Close.

data have;
	input loan_number $10.;
  put loan_number $10. ' -> ' @;
	loan_number=substr("0000000000"||loan_number,1+lengthn(loan_number)) ;
  put loan_number;
datalines;

1234567890
2323333
22345099
112009899
345566
;

           -> 0000000000
1234567890 -> 1234567890
2323333    -> 0002323333
22345099   -> 0022345099
112009899  -> 0112009899
345566     -> 0000345566

Re: Add Leading zero max of 10

novinosrin — Wed, 12 May 2021 16:34:49 GMT

Hi @Q1983 Yet another easy and lazy alternative-

data have;
length
  loan_number $10
  
;
input loan_number ;

datalines;
2323333
22345099
112009899
345566
;
run;

data want;
 set have;
 length need $10;
 need=translate(right(loan_number),'0',' ');
run;

Logic-

Move the contents to the right. Fill the blanks with 0.