topic Re: Reg:Sort Data in the same observation based on comma in SAS Programming

Reg:Sort Data in the same observation based on comma

My_SAS — Fri, 11 May 2012 07:03:55 GMT

Hi i am having data like this

data Temp;
input name $ 1-30;
cards;
cell,van,zim
zim,app,Run
Mor,App,hen
zac,zil,run,fun,app,box,cat

run;

But i want the output in the sort order i dont know how many obs with comma will come

output

cell,van,zim
app,run,zim
app,hen,mor
app,box,cat,fun,run,zac,zil

Re: Reg:Sort Data in the same observation based on comma

Ksharp — Fri, 11 May 2012 07:35:29 GMT

OK. Let me try it.

data Temp;
input name $ 1-30;
cards;
cell,van,zim
zim,app,Run
Mor,App,hen
zac,zil,run,fun,app,box,cat
zac,bil
;
run;
proc sql noprint;
select max(count(name,','))+1 into : max from temp;
quit;

data want;
 set temp;
 array _a{&max} $ ;
 do i=1 to &max;
  _a{i}=lowcase(scan(name,i,','));
 end;
 call sortc(of _a{*});
 name=catx(',',of _a{*});
 drop i _a:;
run;

Ksharp

Re: Reg:Sort Data in the same observation based on comma

My_SAS — Fri, 11 May 2012 09:33:58 GMT

Thqs Ksharp

Re: Reg:Sort Data in the same observation based on comma

sas_Forum — Fri, 18 May 2012 14:01:58 GMT

Hi khsarp some times i will run my job with 0 records when i do this i am getting Error what can i do

as we run in DI and we run this job daily some times we get o kb file then also we run the job then job fails

what can i do for this.

data Temp;

input name $ 1-30;

cards;

;

run;

proc sql noprint;

select max(count(name,','))+1 into : max from temp;

quit;

data want;

set temp;

array _a{&max} $ ;

do i=1 to &max;

_a{i}=lowcase(scan(name,i,','));

end;

call sortc(of _a{*});

name=catx(',',of _a{*});

drop i _a:;

run;

Re: Reg:Sort Data in the same observation based on comma

Ksharp — Mon, 21 May 2012 02:54:20 GMT

data Temp;
input name $ 1-30;
cards;
;
run;



%macro sort_char;
%let dsid=%sysfunc(open(temp));
%let nobs=%sysfunc(attrn(&dsid,nobs));
%let dsid=%sysfunc(close(&dsid));
%put &nobs ;
%if &nobs=0 %then %return;
proc sql noprint;
select max(count(name,','))+1 into : max from temp;
quit;

data want;
 set temp;
 array _a{&max} $ ;
 do i=1 to &max;
  _a{i}=lowcase(scan(name,i,','));
 end;
 call sortc(of _a{*});
 name=catx(',',of _a{*});
 drop i _a:;
run;
%mend sort_char;

%sort_char

Ksharp