topic ODS noproctitle has no effect in ods html in SAS Programming

ODS noproctitle has no effect in ods html

Jean-Jacques — Tue, 04 May 2021 18:17:16 GMT

I am trying to suppress the PROC title in html output. I am using the ODS noproctitle option, but the PROC title is still appearing in the output.
What could be wrong?

ods listing close;
ods noproctitle;
ods html style=daisy file='test.html' path=".";
title "y=a+bxlnx";
ods graphics on;
proc nlin data=exposure method=Marquardt noitprint plots=fitplot(stats=default(rmsincurv rmspecurv));
by study harvest;
parameters A=1 to 201 by 20 B=-0.000001;
bounds B<0;
model response=A+B*exposure*log(exposure);
output out=RESULTS parms=A B predicted=pyDW;
run;

ods graphics off;
title;
ods html close;
ods listing;

Re: ODS noproctitle has no effect in ods html

Reeza — Tue, 04 May 2021 18:27:35 GMT

Put the ODS NOPROCTITLE after your ODS HTML statement.

FYI - I cannot replicate your issue under a variety of tests. Please include your log, your SAS version and ensure you're looking at the correct output file. It would help if you can replicate the problem with a simpler proc, ie PROC FREQ so that anyone can run your code.

Code I ran:

ods listing close;
ods noproctitle;
ods html style=daisy file='test.html' path="/home/fkhurshed/";
title "y=a+bxlnx";
ods graphics on;
proc freq data=sashelp.class;
table age*sex;
run;

ods graphics off;
title;
ods html close;
ods listing;

Output seen:

No title, as per NOPROCTITLE.

Re: ODS noproctitle has no effect in ods html

Reeza — Tue, 04 May 2021 18:28:12 GMT

Tested on SAS 9.4M6 (SAS On Demand for Academics, SAS Studio).

Re: ODS noproctitle has no effect in ods html

Jean-Jacques — Tue, 04 May 2021 18:44:57 GMT

Thanks for taking a look at this.

I am running SAS 9.4 TS 1M6 on X64_10PRO

I tested the following code, and ods noproctitle worked perfectly as intended. This seems very odd to me. The only thing I changed is the PROC. Could it be an NLIN-specific issue?

ods noproctitle;
ods listing close;
ods html style=daisy file='test.html' path=".";
title "TEST NOPROCTITLE";
ods graphics on;

proc reg data=sashelp.class;
model Weight = Height;
run;

ods graphics off;
title;
ods html close;
ods listing;

Re: ODS noproctitle has no effect in ods html

Reeza — Tue, 04 May 2021 18:52:06 GMT

It does appear to be a bit of a bug with the NLIN proc - Time to open a SAS Support ticket.

Re: ODS noproctitle has no effect in ods html

Jean-Jacques — Tue, 04 May 2021 19:15:14 GMT

It looks like it.

I ran the following and ODS noproctitle had no effect. "The NLIN procedure" appeared in the output as a title.

ods listing close;
ods noproctitle;
ods html style=daisy file='test.html' path=".";
title "TEST NOPROCTITLE";
ods graphics on;

proc NLIN data=sashelp.class;
parms A=0 B=1;
model Weight = A+B*Height;
run;

ods graphics off;
title;
ods html close;
ods listing;

Re: ODS noproctitle has no effect in ods html

Reeza — Tue, 04 May 2021 19:58:09 GMT

Yes, I saw the same behaviour but only with PROC NLIN. Note that I tested PROC FREQ + NLIN but not other procs.