topic Re: PROC SGPLOT BLOCK options in SAS Programming

PROC SGPLOT BLOCK options

Recep — Mon, 03 May 2021 22:14:10 GMT

Hello all,

Can I use the "BLOCK" option with VBAR statement in PROC SGPLOT? The example below shows that it works with SCATTER but I could not make it work with VBAR?

Thanks a lot in advance!

Recep

DATA test;
INPUT Hospital $ age_group $ count level $;
CARDS;
Hosp1 0-16 0 Level1
Hosp1 17-74 10 Level1
Hosp1 75+ 1 Level1
Hosp2 0-16 14 Level1
Hosp3 0-16 1 Level1
Hosp3 17-74 16 Level1
Hosp4 0-16 1 Level2
Hosp4 17-74 4 Level2
Hosp5 17-74 7 Level2
Hosp6 17-74 80 Level2
Hosp6 75+ 2 Level2
Hosp7 17-74 4 Level3
Hosp8 17-74 9 Level3
Hosp9 17-74 95 Level3
Hosp9 75+ 1 Level3
Hosp10 0-16 1 Level3
Hosp10 17-74 27 Level3
;
RUN;

proc sgplot data=test;
block x=hospital block=level / filltype=alternate fillattrs=GraphAltBlock altfillattrs=GraphBlock transparency=0.7;
scatter x=hospital y=count/ group=age_group
grouporder=ascending
MARKERATTRS=(symbol=circlefilled size=10)
LEGENDLABEL= "Hospitalizations"
datalabel
datalabelpos=top;

xaxis display=all fitpolicy=rotate grid;
yaxis offsetmin=0.02 grid;
title ' ';
run;

proc sgplot data=test;
block x=hospital block=level / filltype=alternate fillattrs=GraphAltBlock altfillattrs=GraphBlock transparency=0.7;
vbar hospital / response=count
group=age_group
stat=sum
datalabel
datalabelattrs=(weight=bold)
nooutline
barwidth=0.5;
xaxis display=(nolabel);
yaxis grid label='Number of hospitalizations';
title ' ';
run;

Re: PROC SGPLOT BLOCK options

Reeza — Mon, 03 May 2021 22:20:34 GMT

VBARPARM is usually required when you want to combine different graph types. Can you show a bit of what you're trying to do?

Re: PROC SGPLOT BLOCK options

Recep — Mon, 03 May 2021 22:25:44 GMT

Thanks @Reeza ! I'm trying to replicate the BLOCK option in the first SGPLOT example with SCATTER in the second example with VBAR. If you run the examples you can see that hospitals are grouped by their "Levels" in the SGPLOT with SCATTER but not with the VBAR.

Re: PROC SGPLOT BLOCK options

BrunoMueller — Tue, 04 May 2021 09:18:48 GMT

Have a look here for the Plot Type Compatibility:
https://go.documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/grstatproc/p0yud64khw8fuin1xgr85dgxbb7t.htm

So as @Reeza mentioned to combine SCATTER, BLOCK and a bar chart you have to use VBARPARM or VBARBASIC.

For VBARPARM you need to precalculate the values you want to plot.

Change VBAR to VBARBASIC in your second SGPLOT and you should get what you need.

Also have a look at this blog post https://blogs.sas.com/content/iml/2021/04/14/overlay-graphs-basic-bar-chart.html by @Rick_SAS

Re: PROC SGPLOT BLOCK options

Recep — Tue, 04 May 2021 16:46:40 GMT

Thanks @BrunoMueller ! Simply changing the VBAR statement to VBARBASIC helped what I wanted to do.

Best,

Recep