topic Re: How do I designate specific character variables date intervals using if...then statements in SAS Programming

How do I designate specific character variables date intervals using if...then statements

ishaqwright21o — Fri, 30 Apr 2021 22:29:15 GMT

I am trying to designate character variables to specific date intervals yet it only produces numerical and does not read quoted statements. I did create a new date variable and was going to do the designations. Please help. Thanks

Data work.date_of_Death;

set work.eclrsvs_fludata_new_NoDupkey;

death_date=input(Dt_Of_death,yymmdd10.);

format death_date mmddyy10.;

if Death_date le 08/01/2020 then Week_No = "2031";

Else if Death_date le 08/08/2020 then Week_No = "2032";

Else if Death_date le 08/15/2020 then Week_No = "2033";

Else if Death_date le 08/22/2020 then Week_No = "2034";

Else if Death_date le 08/29/2020 then Week_No = "2035";

run;

Re: How do I designate specific character variables date intervals using if...then statements

Tom — Fri, 30 Apr 2021 23:06:36 GMT

I am not sure what you are asking about.

The code you posted appears to be creating two variables, but if either one already exists in eclrsvs_fludata_new_NoDupkey then their type (and storage length) has already been defined and cannot be changed.

If you want to explicit about how death_date or Week_No is defined then define them before using them in your assignment statements.

Also why are you comparing date values (which are integers) to the results of those division expressions in your IF conditions?

If you want to compare a date value to a specific date you can use a date literal instead. Date literals are quoted strings that can be converted to a date by the DATE informat followed by the letter D.

data work.date_of_Death;
  set work.eclrsvs_fludata_new_NoDupkey;
  length death_date 8 Week_No $4 ;
  death_date=input(Dt_Of_death,yymmdd10.);
  format death_date mmddyy10.;
  if Death_date le '01AUG2020'd then Week_No = "2031";
  else if Death_date le '08AUG2020'd then Week_No = "2032";
  slse if Death_date le '15AUG2020'd then Week_No = "2033";
  else if Death_date le '22AUG2020'd then Week_No = "2034";
  else if Death_date le '29AUG2020'd then Week_No = "2035";
run;

Re: How do I designate specific character variables date intervals using if...then statements

Patrick — Sat, 01 May 2021 04:50:23 GMT

Here another option for calculating week_no:

data work.eclrsvs_fludata_new_NoDupkey;
  do _dt='01aug2020'd, '02aug2020'd,'01Jul2020'd to '20Sep2020'd by 5;
    Dt_Of_death=put(_dt,yymmdd10.);
    output;
  end;
  drop _dt;
  stop;
run;

data work.date_of_Death;
  set work.eclrsvs_fludata_new_NoDupkey;
  length death_date 8 Week_No $4;
  death_date=input(Dt_Of_death,yymmdd10.);

  format death_date mmddyy10.;
  retain _base_dt;
  format _base_dt date9.;
  if _n_=1 then _base_dt=intnx('week','01AUG2020'd,-2031,'b');
  week_no=put(intck('week',_base_dt,death_date), z4.);
/*  drop _base_dt;*/
run;