topic Re: removing all the variables without any observations from my dataset in SAS Programming

removing all the variables without any observations from my dataset

Emma_at_SAS — Wed, 28 Apr 2021 17:16:26 GMT

I am checking the variables with missing observations in my dataset (using the code below). Now, I want to remove the variables that contain no observations from my dataset. I think about 10% of my variables are all missing observations. My sample size is 2100 and I have 1500 variables. I appreciate your suggestions. Thanks

data count_missing; set &dataset; run;

proc format;
 value $missfmt ' '='Missing' other='Not Missing';
 value  missfmt  . ='Missing' other='Not Missing';
run;
 
proc freq data=count_missing; 
format _CHAR_ $missfmt.; /* apply format for the duration of this PROC */
tables _CHAR_ / missing missprint nocum nopercent;
format _NUMERIC_ missfmt.;
tables _NUMERIC_ / missing missprint nocum nopercent;
run;

Re: removing all the variables without any observations from my dataset

PaigeMiller — Wed, 28 Apr 2021 17:54:27 GMT

Example using SASHELP.ZIPMIL (which has lots of missings), using the NLEVELS option of PROC FREQ

ods output nlevels=nlevels;
proc freq data=sashelp.zipmil nlevels; 
format _CHAR_ $missfmt.; /* apply format for the duration of this PROC */
tables _CHAR_ / missing missprint nocum nopercent;
format _NUMERIC_ missfmt.;
tables _NUMERIC_ / missing missprint nocum nopercent;
run;

proc sql noprint;
    select tablevar into :varnames separated by ' ' from nlevels where nnonmisslevels=0;
quit;

data want;
    set sashelp.zipmil(drop=&varnames);
run;

Re: removing all the variables without any observations from my dataset

PaigeMiller — Wed, 28 Apr 2021 17:34:04 GMT

Also, your formats are not needed, even though I left them in the code.

Re: removing all the variables without any observations from my dataset

sbxkoenk — Wed, 28 Apr 2021 17:39:49 GMT

Hello,

I advise you to search the SAS-communities first to find your answer (before asking your question).

It may save you some valuable time!

This question, for example, is posted rather frequently.

See for example:

Deleting Variables with Only Missing Values from Dataset with 4000+ Variables

https://communities.sas.com/t5/New-SAS-User/Deleting-Variables-with-Only-Missing-Values-from-Dataset-with/td-p/494926

You will find multiple solutions there.

Koen

Re: removing all the variables without any observations from my dataset

Emma_at_SAS — Wed, 28 Apr 2021 18:01:53 GMT

Thank you, PaigeMiller. It works very well!

Re: removing all the variables without any observations from my dataset

Emma_at_SAS — Wed, 28 Apr 2021 18:03:33 GMT

Hi Koen,
Thank you, for your advice. Next time, I will search the previous posts more carefully.
Thanks,
Mary

Re: removing all the variables without any observations from my dataset

Ksharp — Thu, 29 Apr 2021 13:16:40 GMT

https://www.sas.com/content/dam/SAS/support/en/sas-global-forum-proceedings/2020/4737-2020.pdf

Re: removing all the variables without any observations from my dataset

Emma_at_SAS — Thu, 29 Apr 2021 14:02:59 GMT

Great, thank you, Ksharp!