topic Re: converting character date to date9. in SAS Programming

converting character date to date9.

noda6003 — Fri, 23 Apr 2021 09:29:33 GMT

I have character dates and converting them to num date9. but fails to work for char date which is like "2 FEB 2021".

char_date

22 DEC 2020
2 FEB 2021

i use the below step and it works for first record but doesnt work for second one.

ADT=input(char_date, date9.);

How do i get 0 in case day is single digit.

Any clue please

Re: converting character date to date9.

japelin — Fri, 23 Apr 2021 09:37:12 GMT

For example, if you do this and remove the spaces, it will be recognized.

  ADT=input(compress(char_date), date9.);

Re: converting character date to date9.

noda6003 — Fri, 23 Apr 2021 09:43:07 GMT

No, unfortunately it didnt work

Re: converting character date to date9.

japelin — Fri, 23 Apr 2021 09:47:04 GMT

can you provide data that can be reproduced using datalines in the data step?

Re: converting character date to date9.

Kurt_Bremser — Fri, 23 Apr 2021 10:09:28 GMT

To get a leading zero, either use a custom format for DATE9, or use another standard format:

data have;
input char_date $20.;
datalines;
22 DEC 2020
2 FEB 2021
;

proc format;
picture mydate
  other='%0d%b%Y' (datatype=date language=english)
;
run;
  
data want;
set have;
num_date = input(compress(char_date),date9.);
format num_date mydate9.;
run;

data want;
set have;
num_date = input(compress(char_date),date9.);
format num_date yymmdd10.;
run;

Re: converting character date to date9.

Ksharp — Fri, 23 Apr 2021 12:20:19 GMT

data want;
set have;
num_date = input(char_date,date11.);
format num_date date9.;
run;

Re: converting character date to date9.

Tom — Fri, 23 Apr 2021 13:05:11 GMT

Tell the INPUT() function to use the full length of the string instead of truncating at 9 characters.

data have;
  input char_date $11.;
cards;
22 DEC 2020
2 FEB 2021
;

data want;
  set have;
  date = input(char_date,date11.);
  format date date9. ;
run;

Obs     char_date          date

 1     22 DEC 2020    22DEC2020
 2     2 FEB 2021     02FEB2021