topic Re: Seperating the numbers in a single variable in SAS Programming

Seperating the numbers in a single variable

Sowmya12 — Fri, 23 Apr 2021 08:53:14 GMT

Suppose if dataset contains

Id         ict
102     4
103      5,7
;
run;

The output dataset should be

Id       ict
102    4
103     5
103      7

Suggest me how can I get the output as mentioned above

Re: Seperating the numbers in a single variable

japelin — Fri, 23 Apr 2021 09:22:25 GMT

How about this code?

data have;
  length Id 8 ict $8;
  infile datalines dlm=' ';
  input id ict;
datalines;
102 4
103 5,7
;
run;

data want;
  set have;
  tmp_cnt=count(ict,',')+1;
  tmp_ict=ict;
  do i=1 to tmp_cnt;
    ict=scan(tmp_ict,i,',');
    output;
  end;
 
  drop tmp_: i;
run;

(modified.)

Re: Seperating the numbers in a single variable

Kurt_Bremser — Fri, 23 Apr 2021 10:13:14 GMT

You can simplify this with the use of dataset options and use of the COUNTW function in the DO statement:

data want;
set have (rename=(ict=_ict));
do i = 1 to countw(_ict,",");
  ict = scan(_ict,i,",");
  output;
end;
drop i _ict;
run;

Re: Seperating the numbers in a single variable

Kurt_Bremser — Fri, 23 Apr 2021 10:16:27 GMT

PS if you want numbers, add an INPUT function:

data want;
set have (rename=(ict=_ict));
do i = 1 to countw(_ict,",");
  ict = input(scan(_ict,i,","),32.);
  output;
end;
drop i _ict;
run;