topic Re: want to create three variable in SAS Programming

want to create three variable

aanan1417 — Thu, 22 Apr 2021 04:29:10 GMT

i want to create three variable using a string

a ='rahul99yadav'

output should be

first_name last_name Id

rahul yadav 99

Re: want to create three variable

KentaMURANAKA — Thu, 22 Apr 2021 04:53:31 GMT

I do not know what structure your data have, but how about this?

data test;
    length x $200.;
    input x $;
    datalines;
    taro01yamada
    gonbe02nanashi
    ;
run;


data test_1;
    set test;


    attrib first last id length=$200.;


    v=verify(x, "abccdefghijklmnopqrstuvwxyz");


    first=substr(x, 1, verify(x, "abccdefghijklmnopqrstuvwxyz")-1);
    last=substr(substr(x, verify(x, "abccdefghijklmnopqrstuvwxyz")), verify(substr(x, verify(x, "abcdefghijklmnopqrstuvwxyz")), "0123456789"));
    id=substr(substr(x, verify(x, "abccdefghijklmnopqrstuvwxyz")), 1, verify(substr(x, verify(x, "abcdefghijklmnopqrstuvwxyz")), "0123456789")-1);
run;

Re: want to create three variable

japelin — Thu, 22 Apr 2021 05:10:13 GMT

please try this code.

data have;
  length a $200;
  input a;
datalines;
rahul99yadav
;
run;

data want;
  set have;
  length first_name $20 last_name $20 Id $8;
  first_name=scan(a,1,,'d');
  last_name =scan(a,2,,'d');
  Id=scan(a,1,,'dk');
run;

Re: want to create three variable

andreas_lds — Thu, 22 Apr 2021 05:10:53 GMT

Have you used regular expressions?

data have_want;
    length 
        first_name last_name $ 40 
        id $ 10
    ;
    
    rx = prxparse('/(\D+)(\d+)(\D+)/');
    
    a ='rahul99yadav';
    
    if prxmatch(rx, a) then do;
        first_name = prxposn(rx, 1, a);
        id = prxposn(rx, 2, a);
        last_name = prxposn(rx, 3, a);       
    end;
    
    drop rx;
run;

Re: want to create three variable

aanan1417 — Thu, 22 Apr 2021 05:59:16 GMT

Thanks a ton

Re: want to create three variable

Ksharp — Thu, 22 Apr 2021 11:55:41 GMT

Does it exactly have three variables ?

data test;
    length x $200.;
    input x $;
    datalines;
    taro01yamada
    gonbe02nanashi
    ;
run;

data want;
 set test;
 v1=scan(x,1,,'d');
 v2=scan(x,2,,'d');
 v3=scan(x,1,,'kd');
run;

Re: want to create three variable

aanan1417 — Thu, 22 Apr 2021 16:00:18 GMT

Thanks a ton