topic Re: How to simulate two parameters with correlation of 0.8 in SAS Programming

How to simulate two parameters with correlation of 0.8

superbug — Wed, 07 Apr 2021 13:50:36 GMT

I want to simulate two parameters a* and b satisfying the following conditions. How should I simulate these two parameter so that the correlation of them is 0.8. Thanks much for the help!

Re: How to simulate two parameters with correlation of 0.8

PaigeMiller — Wed, 07 Apr 2021 13:58:04 GMT

https://blogs.sas.com/content/iml/2017/09/25/simulate-multivariate-normal-data-sas-simnormal.html

Re: How to simulate two parameters with correlation of 0.8

Reeza — Wed, 07 Apr 2021 14:04:12 GMT

Do you have SAS IML? If so, this could this be considered a multivariate normal distribution?
https://blogs.sas.com/content/iml/2011/01/12/sampling-from-the-multivariate-normal-distribution.html
Note the bottom note about using a correlation matrix instead of a covariance matrix.

Re: How to simulate two parameters with correlation of 0.8

superbug — Wed, 07 Apr 2021 14:15:16 GMT

@Reeza

Thanks much!

I don't have SAS IML.

I don't know how to do this step as well.

Re: How to simulate two parameters with correlation of 0.8

superbug — Wed, 07 Apr 2021 15:01:12 GMT

@PaigeMiller

Thanks much for the information.

Flowing example you provided, I made up my outcorr data, which looks like following table

I use the following code

proc import datafile="....\outcorr.csv"
dbms=csv out=outcorr replace; run;

%let N = 60;            /* sample size */
%let NumSamples = 100;  /* number of samples */
proc simnormal data=work.outcorr outsim=SimMVN
               numreal = %sysevalf(&N*&NumSamples) 
               seed = 12345;          /* random number seed */
   var a b;
run;

However, there is following error message

I am seeing the "outcorr" data has been normally read in. Do you have any idea of what caused this error message?

Again thanks much!

Re: How to simulate two parameters with correlation of 0.8

PaigeMiller — Wed, 07 Apr 2021 15:04:52 GMT

How was OUTCORR created? Can you show us (screen capture is okay) OUTCORR?

Re: How to simulate two parameters with correlation of 0.8

superbug — Wed, 07 Apr 2021 15:06:57 GMT

@PaigeMiller

I manually created outcorr.csv, which looks like following

Re: How to simulate two parameters with correlation of 0.8

PaigeMiller — Wed, 07 Apr 2021 15:09:59 GMT

I will throw this question over to @Rick_SAS to see if he has any ideas why you are getting an error.

Re: How to simulate two parameters with correlation of 0.8

superbug — Wed, 07 Apr 2021 15:39:15 GMT

@PaigeMiller

Thanks!

I'll keep you updated once I hear from him.

Re: How to simulate two parameters with correlation of 0.8

Rick_SAS — Wed, 07 Apr 2021 17:13:12 GMT

You can either use a TYPE=CORR or a TYPE=COV matrix as an input matrix to PROC SIMNORMAL. Here is both ways:

data outcorr(type=CORR);
input _TYPE_ $ 1-4 _NAME_ $ 5-6 a b;
datalines ;
MEAN    0      0
STD     0.1225 2
CORR a  1      0.8
CORR b  0.8    1
run;

proc simnormal data=work.outcorr outsim=SimMVN
               numreal = %sysevalf(&N*&NumSamples) 
               seed = 12345;          /* random number seed */
   var a b;
run;

Or (the harder way, because you have to form the covariance matrix yourself😞

data outcorr(type=COV);
input _TYPE_ $ 1-4 _NAME_ $ 5-6 a b;
datalines ;
MEAN    0      0
COV  a  0.015  0.196
COV  b  0.196  4
run;

%let N = 60;            /* sample size */
%let NumSamples = 100;  /* number of samples */
proc simnormal data=work.outcorr outsim=SimMVN
               numreal = %sysevalf(&N*&NumSamples) 
               seed = 12345;          /* random number seed */
   var a b;
run;

I want to make sure that the OP wants bivariate normal data. The initial post states

a ~ (0, 0.1225)

b ~ (0,2)

I do not know what that notation means. People seem to be interpreting it as

a ~ N(0, 0.1225)

b ~ N(0,2)

which seems likely, but worth verifying with the instructor of the class.

Re: How to simulate two parameters with correlation of 0.8

Rick_SAS — Wed, 07 Apr 2021 15:45:51 GMT

Use PROC SIMNORMAL with the COV matrix that you specify in the image.

Re: How to simulate two parameters with correlation of 0.8

superbug — Wed, 07 Apr 2021 16:01:03 GMT

@Rick_SAS

Thank you SOOO much for your quick response!

Yes, your code worked. The standard expression should be the following as you pointed out

a ~ N(0, 0.1225)

b ~ N(0, 2)

Could you please explain how did you get the numbers in the covariance matrix as following?

COV  a  1.915  0.3873
COV  b  0.3873 4.321

Re: How to simulate two parameters with correlation of 0.8

PaigeMiller — Wed, 07 Apr 2021 16:07:11 GMT

@Rick_SAS wrote:

Here is the correct DATA step to create the input matrix for PROC SIMNORMAL:
data outcorr(type=COV);
input _TYPE_ $ 1-4 _NAME_ $ 5-6 a b;
datalines ;
MEAN    0      0
STD     0.1225 2
COV  a  1.915  0.3873
COV  b  0.3873 4.321
run;

%let N = 60;            /* sample size */
%let NumSamples = 100;  /* number of samples */
proc simnormal data=work.outcorr outsim=SimMVN
               numreal = %sysevalf(&N*&NumSamples) 
               seed = 12345;          /* random number seed */
   var a b;
run;
I want t make sure that the OP wants bivariate normal data. The initial post states

a ~ (0, 0.1225)

b ~ (0,2)

I do not know what that notation means. People seem to be interpreting it as

a ~ N(0, 0.1225)

b ~ N(0,2)

which seems likely, but worth verifying with the instructor of the class.

Well, that seems like an obvious error to me, now that you have pointed it out. COV matrix not CORR matrix. Thanks, @Rick_SAS

Re: How to simulate two parameters with correlation of 0.8

Rick_SAS — Wed, 07 Apr 2021 17:04:00 GMT

I'm very sorry. That was a mistake on my part because I copied/pasted from another source.

From your follow-up post, I assume that N(0,2) means "mean=0 and stdDev=2." If so, the correct covariance matrix should be

COV a 0.015 0.196 COV b 0.196 4

which is the matrix in the second part of the problem. I will edit my solution. Thanks.

Re: How to simulate two parameters with correlation of 0.8

superbug — Wed, 07 Apr 2021 18:05:48 GMT

@Rick_SAS

Thank you!

when I changed it to

COV  a  0.015  0.196
COV  b  0.196  4

and run the code, it has the following error message

Re: How to simulate two parameters with correlation of 0.8

superbug — Wed, 07 Apr 2021 18:15:50 GMT

@Rick_SAS

Please ignore my last message. the error message resolved.

I very much appreciate your help and expertise. Again thanks much!

Re: How to simulate two parameters with correlation of 0.8

Ksharp — Fri, 09 Apr 2021 11:49:55 GMT

So interesting. Maybe you need this ?

data have;
call streaminit(12345678);
do i=1 to 1000;
 x=rand('normal',0,0.1225);
 e=rand('normal',0,0.1225);
 y=0.8*x + sqrt(1-0.8**2)*e;
 output;
end;
run;

proc standard data=have out=temp std=2;
var y;
run;
data want;
 merge have(keep=x) temp(keep=y);
 run;
 proc corr data=want;
var x y;
run;

Re: How to simulate two parameters with correlation of 0.8

superbug — Thu, 08 Apr 2021 17:01:40 GMT

@Ksharp

Thanks much for you alternative input. it is awesome!