topic Re: How to replace the value.. in SAS Programming

How to replace the value..

yaswanthj — Thu, 27 Dec 2012 10:04:36 GMT

Hi All,

I have a data like mentioned below..

data test;

input name $ age;

cards;

aa .

bb 1

cc 2

dd 3

ee .

ff 5

run;

I have to replace the values of age..that means second value should be in first place, 3rd should be in 2nd, 4th should be in 3rd..so on .. Please help me..

Output should be like below/..

Name age

aa 1

bb 2

cc 3

dd .

ee 5

ff .

Thanks

Yaswanth

Re: How to replace the value..

Patrick — Thu, 27 Dec 2012 11:08:20 GMT

Sounds like an excercise so instead of simply asking for the question and learning nothing you should show us what you've already done and where you've got stuck. Just getting solutions won't help you to become a skilled developer.

But o.k., here you go. If it's study: Make sure you understand 100% what's going on here.

data want;

merge test(keep=name) test(keep=age firstobs=2);

run;

Re: How to replace the value..

kuridisanjeev — Thu, 27 Dec 2012 11:24:15 GMT

Hi Patrick

Your solutions looks smart and easy for above post and bellow one too..

But in the context of Huge data,is above method help full?

It might take lot time to process right?

Clarify me...

Thanks

Sanjeev.K

Re: How to replace the value..

yaswanthj — Thu, 27 Dec 2012 11:40:12 GMT

Hi Patrick..

your Mentioned code is working fine ..and also working for below post..

I tried with your code it is working..but it is taking long time when i execute for huge data in V9.1, the folk sanjeev mentioned in this post..

Could you please let me know, is there any other ways to do..with out using merge statement.

Thanks & Regards,

Yaswanth

Re: How to replace the value..

Haikuo — Thu, 27 Dec 2012 14:28:01 GMT

Well, Merge seems to me very efficient if it does not look to match By variables like in this case. Another look-ahead alternative is to try SET statement:

data want;

set test(keep=name);

set test(keep=age firstobs=2) test(obs=1 drop=_all_);

run;

Haikuo

Re: How to replace the value..

joehinson — Thu, 27 Dec 2012 16:18:20 GMT

Here is another approach, almost as efficient as Hai.Kuo's:

data new(keep=name age);

dsid=open("test");

nrows=attrn(dsid,"NOBS");

do k=1 to nrows;

rc1=fetchobs(dsid,k);

name=getvarc(dsid,1);

rc2=fetchobs(dsid,k+1);

age=getvarn(dsid,2);

output;

end;

run;

Re: How to replace the value..

Ksharp — Fri, 28 Dec 2012 02:07:10 GMT

Or put lag() function on variable name.

data test;
input name $ age;
cards;
aa .
bb 1
cc 2
dd 3
ee .
ff 5
;
run;
data want;
 set test end=last;
 _name=lag(name);
if _n_ gt 1  then do;output; 
                    if last then do;_name=name;age=.;output;end;
end;
drop name;

run;

KSharp