topic Floating and integers under one variable in SAS Programming

Floating and integers under one variable

Minku — Wed, 03 Mar 2021 18:43:13 GMT

In one numeric variable I have integers and floating values , I want in new variable (character) integers as it is and floating values with 2 decimal places . Please see the below table and help me ?

data have;

datalines avg;

cards;

5.9090888

6.3

8.1

;

run;

I want like below in character variable as

x( Character variable )

5.91

6.30

8.10

Thanks in advance

Re: Floating and integers under one variable

ErikLund_Jensen — Wed, 03 Mar 2021 19:07:18 GMT

Hi @Minku

A simple solution is the following.

data have;
	input avg;
     datalines;
     1
      5.9090888
      6.3
      58
      8.1
;
run;
data want; set have;
	length x $8;
	if avg = int(avg) then x = left(put(avg,8.0));
	else x = left(put(avg,10.2));
run;

Re: Floating and integers under one variable

AMSAS — Wed, 03 Mar 2021 20:56:06 GMT

And a different approach:

data have;
    infile cards;
	input avg;
    cards;
1
5.9090888
6.3
58
8.1
;

run;

data want ;
	set have ;
	/* Convert avg to character value and format */
	cAvg=putn(avg,"12.2") ;
	/* 12.2 format will force .00 which we now remove with a Perl Reg Expression */
	removeDotZeros=prxchange('s/\.00//',-1,cAvg) ;
	/* Output all 3 values */
	put avg= cAvg= removeDotZeros=;
run ;

Re: Floating and integers under one variable

Minku — Thu, 04 Mar 2021 12:11:08 GMT

Thank you 🙂

Re: Floating and integers under one variable

Minku — Thu, 04 Mar 2021 12:26:50 GMT

Thanks