topic Date Extract in SAS Programming

Date Extract

AP718 — Mon, 01 Mar 2021 14:33:25 GMT

I have a variable with dates in different formats and ranges. The first one is pretty simple. Looking for a way to scan and extract text for the latest date from the other variations so that I end up with the dates in Want and the Format. Please advise. Thanks!

Have	Want	Format
Jan 9, 2018	20180109	YYMMDDN8
April 19,20,25, 2018	20180425	YYMMDDN8
June 7 & 11, 2018	20180611	YYMMDDN8
July 4 - 16, 2018	20180716	YYMMDDN8
Feb 26 - Mar 7, 2018	20180307	YYMMDDN8

Re: Date Extract

yabwon — Mon, 01 Mar 2021 15:00:57 GMT

Like this:

data have;
input Have $ 20. Want yymmdd10.	Format $ 10.;
format Want yymmddn8.;
cards;
Jan 9, 2018	         20180109	YYMMDDN8
April 19,20,25, 2018 20180425	YYMMDDN8
June 7 & 11, 2018    20180611	YYMMDDN8
July 4 - 16, 2018    20180716	YYMMDDN8
Feb 26 - Mar 7, 2018 20180307	YYMMDDN8
;
run;


data want;
  set have;
  length m $ 3;

  m = scan(compress(Have,,'KAS'), -1);
  y = scan(Have, -1);
  d = scan(Have, -2);

  want_new = input(cats(d,m,y), date9.);
  format want_new yymmddn8.;

  compare = (want_new = want);
run;
proc print;
run;

Re: Date Extract

AP718 — Mon, 01 Mar 2021 17:40:44 GMT

Thank you! This worked to convert the dates!