topic converting time to string in one step in SAS Programming

converting time to string in one step

K_S — Wed, 10 Feb 2021 17:59:48 GMT

I have a time variable that looks like this 08:00 and I want it to turn into a string variable that looks the same way.

How would you go about coding this?

Re: converting time to string in one step

Kurt_Bremser — Wed, 10 Feb 2021 18:05:04 GMT

Use the PUT or PUTN function with the same format that is specified for the numeric time variable.

Re: converting time to string in one step

K_S — Thu, 11 Feb 2021 16:16:15 GMT

Thanks. The time variable I have is not numeric. It is a time variable and the numeric formats don't work on it. Any other tips?

Re: converting time to string in one step

Kurt_Bremser — Thu, 11 Feb 2021 16:17:24 GMT

If it is not numeric, then it is already a string (character), so there's no need for converting.

Re: converting time to string in one step

Tom — Thu, 11 Feb 2021 16:33:42 GMT

@K_S wrote:

Thanks. The time variable I have is not numeric. It is a time variable and the numeric formats don't work on it. Any other tips?

SAS only has two data types. Floating point numbers and fixed length character strings. If the variable actually has time values then it contains the number of seconds since midnight. It would only look like '08:00' if you were displaying the value with the TIME5. format.

1335  data _null_;
1336    now=time();
1337    put now= time5. now= comma12. ;
1338  run;

now=11:27 now=41,265

So to convert it to the formatted value use the PUT() or PUTN() function.

data test;
  input time time. ;
  string1=put(time,time5.);
  string2=putn(time,'time5.');
  format time time5.;
  string3=vvalue(time);
  string4=vvaluex('time');
  put (_all_) (=/);
cards;
08:00
11:27
;

1363  data test;
1364    input time time. ;
1365    string1=put(time,time5.);
1366    string2=putn(time,'time5.');
1367    format time time5.;
1368    string3=vvalue(time);
1369    string4=vvaluex('time');
1370    put (_all_) (=/);
1371  cards;


time=8:00
string1=8:00
string2=8:00
string3=8:00
string4=8:00

time=11:27
string1=11:27
string2=11:27
string3=11:27
string4=11:27