topic Re: Read SAS File With Path in SAS Programming

Read SAS File With Path

psrajput — Wed, 10 Feb 2021 09:06:00 GMT

Hi,

How can we read the SAS file along with the folder path?

Example:

/sas/abc/bcd/sasfile.sas7bdat

Re: Read SAS File With Path

Phil_NZ — Wed, 10 Feb 2021 09:34:41 GMT

You can see my topic here. At the end of the day, you must create or relate to a libref..

https://communities.sas.com/t5/SAS-Programming/How-to-call-a-sas7bdat-file-directly-without-referring-the/m-p/717717#M221989

So I will suggest it is a good idea to refer to a directory rather than the file physically itself per se.

As @Tom said:

You can use the same syntax with any other place where you would reference a dataset.

proc means data="C:\downloads\class"; run;

Notice that under the hood SAS will actually create a libref that points to that directory. Example:

proc contents data="C:\downloads\class" out=contents; run;
proc print data=contents;
  var libname memname name type length ;
run;

Results:

Obs    LIBNAME     MEMNAME    NAME      TYPE    LENGTH

 1     WC000001     CLASS     Age         1        8
 2     WC000001     CLASS     Height      1        8
 3     WC000001     CLASS     Name        2        8
 4     WC000001     CLASS     Sex         2        1
 5     WC000001     CLASS     Weight      1        8

Now once you have referenced the file a specific libref will exist and you could use it to reference the dataset instead as long as you are in the same SAS session.

proc means data=WC000001.class; run;

But if you prefer to use the normal libname.memname syntax then it is better to write your own LIBNAME statement so that you have control over the libref that is used as there is not really anyway to know in advance what libref will be generated by using the quoted physical filename syntax.

So use something like this instead:

libname mydata "C:\downloads" ;
proc contents data=mydata.class; 
run;
proc means data=mydata.class;
run;

Re: Read SAS File With Path

Kurt_Bremser — Wed, 10 Feb 2021 09:35:53 GMT

See this:

data "/folders/myfolders/class.sas7bdat";
set sashelp.class;
run;

data class;
set "/folders/myfolders/class.sas7bdat";
run;

libname myfold '/folders/myfolders';

data class;
set myfold.class;
run;

The preferred method is always to use a defined LIBNAME.

Re: Read SAS File With Path

andreas_lds — Wed, 10 Feb 2021 11:21:27 GMT

@Kurt_Bremser wrote:
...

The preferred method is always to use a defined LIBNAME.

Just wanted to a minor emphasis on the preferred way to access datasets. @psrajput: Forget the other method, it will cause trouble sooner than one expects.