topic Re: Pulling day & Month only in SAS Programming

Pulling day & Month only

ColleenCB — Fri, 29 Jan 2021 15:26:50 GMT

Good day,

I am trying to extract just the day and Month dd-mmm from a datetime field.

The data is being pulled via Proc SQL; as the data resides on the SQL server.

e.DateOfBirth give .17MAR1957:00:00:00.000 --> need --> 17-Mar

Its formatting in SQL is datetime (length 8 )

Will appreciate any assistance.

Thank you

Re: Pulling day & Month only

ballardw — Fri, 29 Jan 2021 16:01:15 GMT

Please tell us how you intend to use the value like 17-Mar?

Typically I would use the DATEPART function to create a date value from the datetime and assign an appropriate format. But someone ignoring year may have other thoughts in mind.

You might also need to show how you expect single digit days of the month to appear.

proc format;
picture ddmon 
low-high = '%0d-%3b'   (datatype=date)
;
run;

data example;
   x="17MAR1957:00:00:00.000"dt;
   y=datepart(x);
   format  y ddmon.;
run;

By creating a date value, as in Y, you preserve the option of changing the display appearance by changing the display format as needed.

Re: Pulling day & Month only

LeonidBatkhan — Fri, 29 Jan 2021 16:58:22 GMT

Hi ColleenCB,

Here is how you can get various flavors of day&month:

data _null_;
   length y $6;
   x = '17MAR1957:00:00:00.000'dt;
   y = put(datepart(x),date5.); /* 17MAR */
   put y=;
   y = catx('-',substr(y,1,2),substr(y,3)); /* 17-MAR */
   put y=;
   y = propcase(y); /* 17-Mar */
   put y=;
run;

Hope this helps.

Re: Pulling day & Month only

Tom — Fri, 29 Jan 2021 16:53:57 GMT

Do you really need the hyphen? If not just use DTDATE5. format.

426  data test;
427    dob = '17MAR1957:00:00:00.000'dt ;
428    put dob dtdate5. ;
429  run;

17MAR

Re: Pulling day

ColleenCB — Sun, 31 Jan 2021 08:46:13 GMT

Thank you so much!
This worked perfectly.

Have a wonderful day
Kind Regards
Colleen Bronkhorst
Business Intelligence Analyst
FNB HR Employee Intelligence
1 First Place
BankCity
Tel: 0875 77 77 11

Rate my service:
Click on the link: Thank you for your rating
Select Nominate and enter my F-number 3340945
Select 1 or more Categories you wish to rate my service in
[cid:image001.jpg@01D6F7BE.38024C90]
Click on Nominate
dm

This email is subject to a disclaimer.

Visit the FNB website and view the email disclaimer and privacy notice / policy by clicking the "About FNB + Legal" and "Legal Matters" links.
If you are unable to access our website, please contact us to send you a copy of the email disclaimer or privacy notice / policy .

Re: Pulling day & Month only

ColleenCB — Sun, 31 Jan 2021 08:51:36 GMT

I like the formatting & it also works for my problem.

But not required in this exercise.

Thank you so much for answering me.

Re: Pulling day & Month only

ColleenCB — Sun, 31 Jan 2021 08:53:43 GMT

Thank you so much for this post.

I will need to keep it save and use it more often - practice makes perfect.

This works perfectly for my requirement.

Have a wonderful day