topic Re: Replace last word in a string conditionally in SAS Programming

Replace last word in a string conditionally

finans_sas — Thu, 28 Jan 2021 16:16:22 GMT

Hi Everyone:

I have a data set that looks like this:

ABC INVESTMENT TR CO TR

ABC WORLD CO TRANSPORTATION

ABC SKYE INVESTMENT TR

ABC CLOUD PROPERTY TR

ABC MOVIES PRODUCTION TRUSTME

TRUST YOURSELF TR TRUE TRACTOR

Strings vary in length. My goal is to replace "TR" at the end of the string with "TRUST". I want to do this if and only if the last word is TR. Ideally, the data will look like this:

ABC INVESTMENT TR CO TRUST

ABC WORLD CO TRANSPORTATION

ABC SKYE INVESTMENT TRUST

ABC CLOUD PROPERTY TRUST

ABC MOVIES PRODUCTION TRUSTME

TRUST YOURSELF TR TRUE TRACTOR

I used tranwrd successfully to replace other parts of the strings, but got stuck on the last one. Could you help me with this? I am using SAS 9.4.

Thank you so much!

Re: Replace last word in a string conditionally

ballardw — Thu, 28 Jan 2021 16:28:05 GMT

One way that uses the fact this is the LAST "word".

data example;
   length x $ 100;
   x="ABC INVESTMENT TR CO TR";
   if scan(x,countw(x))='TR' then x=cats(x,'UST');
run;

Potential issue. If your current variable length is such that adding 3 characters would exceed the length of the variable then the value would be truncated.

data example;
   length x $ 25;
   x="ABC INVESTMENT TR CO TR";
   if scan(x,countw(x))='TR' then x=cats(x,'UST');
run;

So you may have to create a new variable with a longer defined length.

Re: Replace last word in a string conditionally

Tom — Thu, 28 Jan 2021 16:31:52 GMT

Just changing it at the end of the lines make it easy. You can just append something to the end of the string and to the end of the string you are asking TRANWRD() to change.

data want;
  set have;
  if scan(string,-1,' ')='TR' then do;
    string=tranwrd(cats(string,'^%|'),'TR^%|','TRUST');
  end;
run;

Otherwise learn how to use the regular expression functions.

Re: Replace last word in a string conditionally

finans_sas — Thu, 28 Jan 2021 17:15:35 GMT

Thank you so much, Tom!

Re: Replace last word in a string conditionally

finans_sas — Thu, 28 Jan 2021 17:16:17 GMT

Thank you so much, ballardw!

Re: Replace last word in a string conditionally

Ksharp — Fri, 29 Jan 2021 12:40:36 GMT

Just for some fun .

data example;
   length x $ 100;
   x="ABC INVESTMENT TR CO TR";
   y=prxchange('s/\btr$/TRUST/i',1,strip(x));
   output;

      x="ABC WORLD CO TRANSPORTATION";
   y=prxchange('s/\btr$/TRUST/i',1,strip(x));
   output;

run;