topic Re: How not to read what is stated in a delimiter in a character variable in SAS Programming

How not to read what is stated in a delimiter in a character variable

iSAS — Thu, 28 Jan 2021 11:19:22 GMT

Below is the program:

data sample;
infile datalines truncover dlmstr=' ' dsd;
length Size dirname $1000;
input Size dirname $;
datalines;
21561 /Folder_no_space/Folder_no_space/Folder with Space/Folder_no_space/file.sas7bdat
;
run;

Problem: Since there is a ' ' in variable dirname, what will only be read are those before ' '. Is there a way to fix this? What I want is for dirname to read even ' '

Thanks

Re: How not to read what is stated in a delimiter in a character variable

Kurt_Bremser — Thu, 28 Jan 2021 11:45:26 GMT

Read size as a number, and use the && modifier:

data sample;
infile datalines truncover dlmstr=' ' dsd;
length Size 8 dirname $1000;
input Size dirname &&:$1000.;
datalines;
21561 /Folder_no_space/Folder_no_space/Folder with Space/Folder_no_space/file.sas7bdat
;

Re: How not to read what is stated in a delimiter in a character variable

iSAS — Thu, 28 Jan 2021 12:10:53 GMT

Thank you for helping. I just have a follow-up question though. How come if my variable dirname have more than 2 spaces, it doesn't read all of it anymore? Below is the code:

data sample;
infile datalines truncover dlmstr=' ' dsd;
length Size 8 dirname $1000;
input Size dirname &&:$1000.;
datalines;
21560 /Folder_no_space/Folder_no_space/One Space/Folder_no_space/file.sas7bdat
21561 /Folder_no_space/Folder_no_space/Two Spaces/Folder_no_space/file.sas7bdat
21562 /Folder_no_space/Folder_no_space/More Spaces/Folder_no_space/file.sas7bdat
;
run;

May I know how to fix it? Thanks

Re: How not to read what is stated in a delimiter in a character variable

Kurt_Bremser — Thu, 28 Jan 2021 12:20:22 GMT

I see no problem:

data sample;
infile datalines truncover dlmstr=' ' dsd;
length Size 8 dirname $1000;
input Size dirname &&:$1000.;
datalines;
21560 /Folder_no_space/Folder_no_space/One Space/Folder_no_space/file.sas7bdat
21561 /Folder_no_space/Folder_no_space/Two Spaces/Folder_no_space/file.sas7bdat
21562 /Folder_no_space/Folder_no_space/More Spaces/Folder_no_space/file.sas7bdat
;

proc print data=sample noobs;
run;

Result:

Size	dirname
21560	/Folder_no_space/Folder_no_space/One Space/Folder_no_space/file.sas7bdat
21561	/Folder_no_space/Folder_no_space/Two Spaces/Folder_no_space/file.sas7bdat
21562	/Folder_no_space/Folder_no_space/More Spaces/Folder_no_space/file.sas7bdat

Please use the "little running man" button for posting code, as the main posting window will reformat your text along HTML conventions (compressing all whitespace to a single blank, for instance).

Re: How not to read what is stated in a delimiter in a character variable

iSAS — Thu, 28 Jan 2021 12:43:48 GMT

Sending the code the have issues when dirname has more then 1 space:
data sample;
infile datalines truncover dlmstr=' ' dsd;
length Size 8 dirname $1000;
input Size dirname &&:$1000.;
datalines;
21560 /Folder_no_space/Folder_no_space/One Space/Folder_no_space/file.sas7bdat
21561 /Folder_no_space/Folder_no_space/Two Spaces/Folder_no_space/file.sas7bdat
21562 /Folder_no_space/Folder_no_space/More Spaces/Folder_no_space/file.sas7bdat
;
run;

Result:
21560 /Folder_no_space/Folder_no_space/One Space/Folder_no_space/file.sas7bdat
21561 /Folder_no_space/Folder_no_space/Two
21562 /Folder_no_space/Folder_no_space/More

Re: How not to read what is stated in a delimiter in a character variable

Kurt_Bremser — Thu, 28 Jan 2021 12:54:57 GMT

Then you need to have quotes around the strings, or use a delimiter other than blank. The ?? works only as long as single blanks are contained in the strings.

And use the "little running man" button for posting code, it is the one right next to the one indicated (which is for logs and other formatted text data):

Re: How not to read what is stated in a delimiter in a character variable

Astounding — Thu, 28 Jan 2021 13:23:31 GMT

Here's a promising approach:

data sample;
infile datalines truncover dlmstr=' ' dsd;
length Size 8 dirname $1000;
input Size @;
dirname = substr(_infile_, 7);
datalines;
21560 /Folder_no_space/Folder_no_space/One Space/Folder_no_space/file.sas7bdat
21561 /Folder_no_space/Folder_no_space/Two  Spaces/Folder_no_space/file.sas7bdat
21562 /Folder_no_space/Folder_no_space/More                                     Spaces/Folder_no_space/file.sas7bdat
;

Even if your real life situation is more complex, these tools should be adaptable to what you are facing. For example, you may need to locate the position of ".sas7bdat" in order to limit what SUBSTR selects.

Re: How not to read what is stated in a delimiter in a character variable

Ksharp — Thu, 28 Jan 2021 13:33:11 GMT

data sample;
infile datalines truncover dlmstr=' ' dsd;
input Size dirname $1000.;
datalines;
21561 /Folder_no_space/Folder_no_space/Folder with Space/Folder_no_space/file.sas7bdat
;
run;

Re: How not to read what is stated in a delimiter in a character variable

novinosrin — Thu, 28 Jan 2021 13:33:59 GMT

Hi @iSAS just an in-formatted input should do?



data sample;
infile datalines truncover ;
input Size dirname $1000.;
datalines;
21560 /Folder_no_space/Folder_no_space/One Space/Folder_no_space/file.sas7bdat
21561 /Folder_no_space/Folder_no_space/Two Spaces/Folder_no_space/file.sas7bdat
21562 /Folder_no_space/Folder_no_space/More Spaces/Folder_no_space/file.sas7bdat
;
run;

Re: How not to read what is stated in a delimiter in a character variable

ballardw — Thu, 28 Jan 2021 15:17:24 GMT

@iSAS wrote:
Thank you for helping. I just have a follow-up question though. How come if my variable dirname have more than 2 spaces, it doesn't read all of it anymore? Below is the code:

data sample;
infile datalines truncover dlmstr=' ' dsd;
length Size 8 dirname $1000;
input Size dirname &&:$1000.;
datalines;
21560 /Folder_no_space/Folder_no_space/One Space/Folder_no_space/file.sas7bdat
21561 /Folder_no_space/Folder_no_space/Two Spaces/Folder_no_space/file.sas7bdat
21562 /Folder_no_space/Folder_no_space/More Spaces/Folder_no_space/file.sas7bdat
;
run;

May I know how to fix it? Thanks

From the documentation on INFILE DSD option:

...

When you specify DSD, SAS treats two consecutive delimiters as a missing value

So if your character value has two blanks you tell SAS that you have ended the first value by including them.

If you must use spaces in the values then you need to find either a better delimiter or change how you read the data, perhaps fixed columns.