topic Re: "DO OVER" is Undocumented for SAS 9.4, Right? in SAS Programming

"DO OVER" is Undocumented for SAS 9.4, Right?

PhilC — Wed, 20 Jan 2021 16:52:00 GMT

I see documentation out there in the SAS site called "CASL Reference" : SAS Help Center: DO OVER Statement. That website displays "SAS 9.4/Viya 3.4" on the top left of my web browser. I am weary of using that to support the argument that DO OVER is documented, since I still do not see "Do Over" in the documentation at SAS Help Center: Dictionary of SAS DATA Step Statements.

Anyone know the status?

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

PaigeMiller — Wed, 20 Jan 2021 16:46:08 GMT

I could never find it in the current documentation, so yes, it's undocumented.

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

Reeza — Wed, 20 Jan 2021 16:50:00 GMT

DO OVER was deprecated in SAS V7.

It's still supported for backwards compatibility, I usually don't recommend using it in production code but some others on here actively disagree with that stance.

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

ballardw — Wed, 20 Jan 2021 17:02:00 GMT

"Do Over" was pretty much deprecated in SAS 6, I believe. SAS tries to make sure that prior code will run so no errors and will work in existing code. Not documenting a bit of code is one way of saying "it works now but you never know when it might stop and probably should not be using it."

The biggest weakness with the "Do Over", at least in my opinion, what that you really can't use two or more arrays in the same loop.

Example: The following code will run, not doing much of anything serious:

data junk;
  array x  x1-x5;
  array z {5};
  do over x;
     x=sum(x,1);
/*     z=sum(z,1);*/
  end;
run;

If you un-comment the z= sum() bit however you will get illegal array reference errors. Or anything using Z in that loop.

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

PhilC — Wed, 20 Jan 2021 17:05:16 GMT

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

Perhaps IT IS documented for SAS 9.4 under CAS/CASL. So it should be said that "it is not documented for 'base SAS programming' "? I think I'm right. Please correct me if you disagree.

Thanks for all the insightful responses so far.

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

Shmuel — Wed, 20 Jan 2021 17:27:15 GMT

Another limitation:

In old SAS versions -

DO OVER was defined as implicit do loop

The indexed DO ( as do i=1 to ...) was defined as explicit do loop

and it generated an error if the data step used both methods.

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

ballardw — Wed, 20 Jan 2021 17:36:39 GMT

@Shmuel wrote:

Another limitation:

In old SAS versions -

DO OVER was defined as implicit do loop

The indexed DO ( as do i=1 to ...) was defined as explicit do loop

and it generated an error if the data step used both methods.

I thought I remembered the implicit/explicit convention but since it isn't the current documentation searching for "implicit" didn't come up with arrays.

I remember learning the "Do over" in SAS 5.18 and thought "cool, no need to keep track of indexes". And then immediately ran into the "can't use two arrays in the same loop", not so cool. Just easier not to use it.

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

Kurt_Bremser — Wed, 20 Jan 2021 18:08:05 GMT

Two different things. One (documented) is a statement in PROC CAS, the other (undocumented) a DATA step statement.

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

Tom — Wed, 20 Jan 2021 18:39:44 GMT

The also have removed the documentation that you don't have to waste time type the dimension (or even using * as a place holder) when defining the array.

But there is no limitation on use multiple arrays.

You just cannot mix implicit and explicit array indexing for the same array.

If you don't tell SAS what variable to use for the implicit index then it will use _I_ .

So here is an example where arrays A and C are indexed implicitly and B is indexed explicitly.

data junk;
  array A A1-A5 (5*1);
  array B B1-B5 (5*2);
  array C C1-C5 ;
  do over a;
    c=a+b[_i_];
  end;
  put (_all_) (=);
run;

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

PhilC — Wed, 20 Jan 2021 20:54:18 GMT

yeah, that's right. thanks @Tom. I was trying to recall the index, _i_, earlier.

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

PeterClemmensen — Thu, 21 Jan 2021 10:05:26 GMT

I like the implicit array and the Do Over syntax. First of all, I like the clean look of it. Also, the syntax makes good sense to me logically: Do this operation over that range of variables. If the syntax does not make sense, I don't know why they replicated it with the Do_Over Hash Object Method (Available since 9.4).

Using multipe Do Over loops though, you have to think about the index variable (_I_ by default).

For example, this fails.

data _null_;
   array a a1-a2 (1:2);
   array b b1-b3 (1:3); 

   do over a;
      do over b;
         put a= b=;
      end;
   end;
run;

This works

data _null_;
   array a(i) a1-a2 (1:2);
   array b(j) b1-b3 (1:3); 

   do over a;
      do over b;
         put a= b=;
      end;
   end;
run;

Re: "DO OVER" is Undocumented for SAS 9.4, Right?

PeterClemmensen — Thu, 21 Jan 2021 07:05:28 GMT

Interesting 🙂