topic Re: How do I set macro variable to the last week number of 2020 to 53 and not 52 in SAS Programming

How do I set macro variable to the last week number of 2020 to 53 and not 52

PerBundgaard — Thu, 14 Jan 2021 14:54:22 GMT

We have a scheduled task running each Monday morning setting start and stop date to the dates of the previous week, week starting Mondays

For example when running on 4'th January 2021 it sets the start and stop date to 28Dec2020 and 03 Jan2021 as follows:

%LET STARTDATE = %sysfunc(intnx(DAY,(%sysfunc(intnx(WEEK,(%SYSFUNC(today(),)),-1,b),)),+1),date9.);
%PUT &STARTDATE;
%LET STOPDATE = %sysfunc(intnx(DAY,(%sysfunc(intnx(WEEK,(%SYSFUNC(today(),)),-1,e),)),+1),date9.);
%PUT &STOPDATE;

We set another macro variable to the corresponding week number

With this year 2020/2021 we don't seem to be able to get the week number right (=53) using the intnx function ...

%LET WEEK = %sysfunc(intnx(WEEK,(%SYSFUNC(today(),)),0),weeku3.);

Please suggest solution which would set the week number for running on 04Jan2021 to '53' and on 11Jan2021 to '01'

Thanks

Re: How do I set macro variable to the last week number of 2020 to 53 and not 52

novinosrin — Thu, 14 Jan 2021 15:10:29 GMT

Hi @PerBundgaard Are you looking to do this?

%LET WEEK=%sysfunc(week(%sysfunc(intnx(WEEK,%SYSFUNC(today()),-1)),v));
%put &=week;

14         %LET WEEK=%sysfunc(week(%sysfunc(intnx(WEEK,%SYSFUNC(today()),-1)),v));
15         %put &=week;
WEEK=53

And likewise, for current week, setting the increment to 0-

14         %LET WEEK=%sysfunc(week(%sysfunc(intnx(WEEK,%SYSFUNC(today()),0)),v));
15         %put &=week;
WEEK=1

Re: How do I set macro variable to the last week number of 2020 to 53 and not 52

PerBundgaard — Thu, 14 Jan 2021 16:08:13 GMT

Ahh, OK, the ‘v’ descriptor and the week function on top 😊
%LET WEEK = ;
%LET WEEK=W%sysfunc(week(%sysfunc(intnx(WEEK,'04Jan2021'D,0)),v));
%put &=week;

Thanks a lot !

Re: How do I set macro variable to the last week number of 2020 to 53 and not 52

PerBundgaard — Fri, 15 Jan 2021 08:11:29 GMT

Ended up with this solution, including leading zeros, Thanks again !
%LET WEEK=W%sysfunc(week(%sysfunc(intnx(WEEK,%SYSFUNC(today()),0)),v),z2.);
%put &=week;
WEEK=W01