topic Re: How to modify scatter plots (proc scatter)? in SAS Programming

How to modify scatter plots (proc scatter)?

Denali — Tue, 12 Jan 2021 18:00:27 GMT

Hi,

I made a scatter plot using below code.

proc sort data=cp_new;
by Titer;
run;

PROC sgscatter DATA=CP_new;
PLOT Titer * IMC_Titer_RBD_1
/datalabel = Titer group = Titer;
RUN;

How do I:

1. Fill in the colors into the circles?

2. Make the fonts bigger?

3. Change the these pastel colors to brighter colors? The grient colors are great ideas too because these are 0, 160, 200, 400, 600, 800... levels.

4. Export the picture with higher resolution for publication purpose, e.g. 300 dpi?

Thank you very much in advance!

Re: How to modify scatter plots (proc scatter)?

Reeza — Tue, 12 Jan 2021 18:06:46 GMT

I would use SGPLOT instead. Then look at the STYLEATTRS line to customize your graphs. Attribute maps are a good way to control the colours for each point and grouping.

https://documentation.sas.com/?cdcId=pgmsascdc&cdcVersion=9.4_3.5&docsetId=grstatproc&docsetTarget=p1lcbd3lhs3t3bn1jk6d8sjt2yqx.htm&locale=en

Discrete attribute maps
https://documentation.sas.com/?cdcId=pgmsascdc&cdcVersion=9.4_3.5&docsetId=grstatproc&docsetTarget=n18szqcwir8q2nn10od9hhdh2ksj.htm&locale=en

Re: How to modify scatter plots (proc scatter)?

PGStats — Wed, 13 Jan 2021 05:13:39 GMT

Here is an example to get you on the way

ods listing gpath="/home/pg/SASforum/Graphs";
ods graphics imagename="Iris example" image_dpi=300 width=12cm height=9cm;

proc sgplot data=sashelp.iris noautolegend;
format species $3.; /* Keep only 3 letters of species names as labels */
styleattrs datasymbols=(circlefilled) datacontrastcolors=(vividred vividblue palegreen);
scatter y=petalLength x=sepalLength / 
    jitter datalabel=species group=species datalabelattrs=(size=6);
xaxis offsetmin=0.05 offsetmax=0.05; /* Add extra space around the data area */
yaxis offsetmin=0.05 offsetmax=0.05;
run;