topic Re: proc format CNTLIN dataset values in SAS Programming

proc format CNTLIN dataset values

Bala_SD — Thu, 24 Dec 2020 09:24:43 GMT

I am using the dataset to create the formats and in that I have coded values itself has "LOW", "HIGH" when i create formats out of it I am getting error "ERROR: These two ranges overlap: ". I gave the Type also as "C" to consider as character format but still sas is treating "LOW" /"HIGH" as key words and treating as range..Kindly help to resolve this. Below is an example dataset created to explain for example. Is there a way to mask this? For all others I am able to create the formats without any issues.

/****************************************/
data fmt;
retain fmtname "$NRIND";
length start $100. label $100.;
start = "ABNORMAL";
label = "abnormal";
type = "C";
output;
start = "NORMAL";
label = "normal";
type = "C";
output;
start = "HIGH";
label = "high";
type = "C";
output;
start = "LOW";
label = "low";
type = "C";
output;
run;

proc format cntlin=fmt;
run;

/****************log************/

97 proc format cntlin=fmt;
ERROR: These two ranges overlap: LOW-LOW and ABNORMAL-ABNORMAL (fuzz=0).
ERROR: These two ranges overlap: HIGH-HIGH and NORMAL-NORMAL (fuzz=0).
98 run;

WARNING: RUN statement ignored due to previous errors. Submit QUIT; to terminate the procedure.
NOTE: PROCEDURE FORMAT used (Total process time):
real time 0.00 seconds
cpu time 0.00 seconds

Re: proc format CNTLIN dataset values

Kurt_Bremser — Thu, 24 Dec 2020 08:44:14 GMT

Don't use DATATYPE, you don't need it here, and it has a special function.

data fmt;
retain
  fmtname "$NRIND"
  type "C"
;
length start $10. label $10.;
input start label;
datalines;
ABNORMAL abnormal
NORMAL normal
HIGH high
LOW low
;

Re: proc format CNTLIN dataset values

Bala_SD — Thu, 24 Dec 2020 08:56:16 GMT

Thanks for the reply.. The problem is in the procedure creating the formats.. I tried creating the dataset as you suggested, but still getting the same error.

117 data fmt;
118 retain
119 fmtname "$NRIND"
120 type "C"
121 ;
122 length start $10. label $10.;
123 input start label;
124 datalines;

NOTE: The data set WORK.FMT has 4 observations and 4 variables.
NOTE: DATA statement used (Total process time):
real time 0.01 seconds
cpu time 0.00 seconds

129 ;
130 run;
131
132
133 proc format cntlin=fmt;
ERROR: These two ranges overlap: LOW-LOW and ABNORMAL-ABNORMAL (fuzz=0).
ERROR: These two ranges overlap: HIGH-HIGH and NORMAL-NORMAL (fuzz=0).
134 run;

WARNING: RUN statement ignored due to previous errors. Submit QUIT; to terminate the procedure.
NOTE: PROCEDURE FORMAT used (Total process time):
real time 0.00 seconds
cpu time 0.00 seconds

Re: proc format CNTLIN dataset values

Shmuel — Thu, 24 Dec 2020 09:00:49 GMT

LOW and HIGH are reserved word of format procedure, usually used as:

LOW - <value1>

<valuen> - HIGH

that the reason you got the These two ranges overlap:

"These two ranges overlap:" error messages.

Beyond, I had never used the DATATYPE= variable and you can omit it.

As @Kurt_Bremser have shown you can add the TYPE to the RETAIN statement.

Re: proc format CNTLIN dataset values

Bala_SD — Thu, 24 Dec 2020 10:23:35 GMT

Thanks for the reply. Datatype I just used for checking and without removing it i posted here. Yes it is treating "LOW"/"HIGH" as a reserved word only when i create formats from datasets using cntlin.. but if i create seperate format using the usual way it is not treating it as a reserved word and format is created without any issues.. So is there any way to mask this considering as a reserved word and consider to treat as just text while using cntlin ?
proc format;
value $NRIND
"ABNORMAL" = "abnormal"
"NORMAL" = "normal"
"HIGH"="high"
"LOW"= "low"
;
run;

Re: proc format CNTLIN dataset values

Kurt_Bremser — Thu, 24 Dec 2020 11:45:24 GMT

Add the HLO variable, so that it becomes clear these are not the usual HIGH and LOW values:

data fmt;
retain
  fmtname "$NRIND"
  type "C"
  hlo ""
;
length start $10. label $10.;
input start label;
datalines;
ABNORMAL abnormal
NORMAL normal
HIGH high
LOW low
;

proc format cntlin=fmt;
run;

Log:

 73         data fmt;
 74         retain
 75           fmtname "$NRIND"
 76           type "C"
 77           hlo ""
 78         ;
 79         length start $10. label $10.;
 80         input start label;
 81         datalines;
 
 NOTE: The data set WORK.FMT has 4 observations and 5 variables.
 NOTE:  Verwendet wurde: DATA statement - (Gesamtverarbeitungszeit):
       real time           0.00 seconds
       cpu time            0.00 seconds
       
 
 86         ;
 87         
 88         proc format cntlin=fmt;
 NOTE: Format $NRIND is already on the library WORK.FORMATS.
 NOTE: Format $NRIND has been output.
 89         run;

Re: proc format CNTLIN dataset values

Bala_SD — Thu, 24 Dec 2020 14:36:30 GMT

Thanks for the solution

Re: proc format CNTLIN dataset values

mitiksh — Tue, 22 Aug 2023 15:24:18 GMT

Do it like this it will work

data test_fmt;
length label $15;
fmtname='range';
input start $ end $ label :$;
datalines;
LOW 20 "good"
21 high "excellent"
other . "missing"
;
run;