topic data step/programming in SAS Programming

data step/programming

Haiyi_SAS — Tue, 15 Dec 2020 00:21:17 GMT

Hi,

I have following question, and respondent can check all that apply thus multiple categories (see data). How can I break multiple responses such as 1,4,5,6 into separate question and response? Thank you very much! Haiyi

What TV network did you watch? Please check all that apply

▢ NBC (1)

▢ CBS (2)

▢ CNN (3)

▢ Fox (4)

▢ ABC (5)

▢ pbs (6)

Obs network

1 1,4,5

2 1,4,5,6,

3 2

4 1,3,4

5 1,3,4,5,6

Re: data step/programming

ballardw — Tue, 15 Dec 2020 01:04:29 GMT

How really depends on what your current data SAS data set looks like and what you expect the output to look like.

Typically with something like this I prefer to have variables that are coded 1 (for selected) and 0 (not selected).

If that is what you want you might look at the survey software used as that may be an Export option (I know at least 4 different software packages this is the case.) and avoid the whole issue.

Or maybe something like this:

data have;
   input obs network :$10.;
datalines;
1            1,4,5
2            1,4,5,6
3            2
4            1,3,4
5            1,3,4,5,6
;

data want;
   set have;
   array n   NBC CBS  CNN  Fox 
             ABC PBS;
   /* set all the neworks to 0*/
   do i= 1 to dim(n);
      n[i] = 0;
   end;
   /* if the networks number is 
      in the value then set the 
      value of the individual network variable to
      1
   */
  do i=1 to countw(network,',');
     n[input(scan(network,i),best.)] = 1;
  end;
  drop i;
run;

Arrays are a way to reference multiple variables that you intend to do something similar with each.

You reference the individual variable by using the array name, N above, followed by an index or position value in parentheses or brackets. N(3) above would be the CNN variable.

The DIM function returns the number of elements (variables) in an array. So if you add or remove a variable in the Array definition the code adjusts.

The Countw function as used returns the number of elements separated by commas. CAUTION: If you actually have commas with no value afterward then the array usage will return an error.

The fancy code in this: n[input(scan(network,i),best.)] uses the Scan function to get one of the "numbers" from the list and then uses the Input function to create a numeric value so the array index is appropriate. Indexes for arrays must be integers so if you have something that causes values like 1, 2.4, 6 there will be an error.

Re: data step/programming

Astounding — Tue, 15 Dec 2020 01:07:18 GMT

First you need a plan.
Right now you have a single variable called NETWORK. When this is done, do you want 6 variables instead (such as Network1 through Network6, all either "Y" or "N")? Do you have something else in mind?

Re: data step/programming

JulieLearnsSAS — Tue, 15 Dec 2020 11:10:44 GMT

After considering the other answers you've been given, you will probably want to think of something like this: https://communities.sas.com/t5/SAS-Programming/How-to-get-all-possible-multiplicative-interactions/td-p/67009

Best of luck,

Julez.