topic Re: Required operator not found in expression error in macro in SAS Programming

Required operator not found in expression error in macro

David_Billa — Fri, 11 Dec 2020 11:07:06 GMT

I've the below data step which is working fine. However when I tried to convert it into macros, it's not working as I got the error as 'ERROR: Required operator not found in expression: filename(fref,"&dir1.") = 0'

%let dir1=/var/data/server/files;

/*get file details from dir1*/
data files;
fref = "DIR1";
if filename(fref,"&dir1.") = 0
then do;
  did = dopen(fref);
  if did ne 0
  then do;
    do i = 1 to dnum(did);
      name = dread(did,i);
      if upcase(scan(name,-1,".")) = "CSV" then output;
    end;
    did = dclose(did);
  end;
  rc = filename(fref);
end;
keep name;
run;

/*macro variables for digit value from each file*/
data _null_;
set files;
digits = scan(name,5,'_');
call symputx(cats("id",_n_),digits);
run;

When I convert it into macros,

 %if <condition> %then %do;

    data files;
    fref = "DIR1";
    %if filename(fref,"&dir1.") = 0
    %then %do; 
    did = dopen(fref);
    %if did ne 0
    %then %do;
    %do i = 1 %to dnum(did);
    name = dread(did,i);
    %if upcase(scan(name,-1,".")) = "CSV" %then output;
    %end;
    did = dclose(did);
    %end;
    rc = filename(fref);
    %end;
    keep name;
     run;

    /*macro variables for digit value from each file*/
    data _null_;
    set files;
    digits = scan(name,5,'_');
    call symputx(cats("id",_n_),digits);
    run;

    %end;

Once the macro version works, I want to add this portion in the existing macro program and so I want the solution only in macro.

Log:

SYMBOLGEN:  Macro variable DIR1 resolves to /var/data/server/files
ERROR: Required operator not found in expression: filename(fref,"&dir1.") = 0

Any help?

Re: Required operator not found in expression error in macro

Shmuel — Fri, 11 Dec 2020 11:25:43 GMT

You replaced the IF into %IF, in that case sas expects to find a macro variable like &xxx following the %IF.

To convert a sas code into macro you should convert it like in next example:

suppose your code is:

data want;
  set have;
       if var = 1234 then do ; .... end;
run;

then while converting it to macro you need to choose what objects should be supplied

(a dataset name, a variable name, a variable value, part of a statement etc.);

You don't convert IF into %IF.

%macro doit(input, value);
    data want;
      set &input;
           if var = &value then do ; .... end;
    run;
%mend doit;
%doit(have,1234);

Re: Required operator not found in expression error in macro

David_Billa — Fri, 11 Dec 2020 11:58:43 GMT

Can't we convert my code without parameters? My dataset code is different than in your example as I can't pass the value to the Parameters like you shown. I would like to know how to convert my code as macro and without Parameters and any hardcoding like you shown in your example.

Re: Required operator not found in expression error in macro

andreas_lds — Fri, 11 Dec 2020 12:43:33 GMT

There are so many conceptual errors in your attempt to convert the data step into macro, i don't know where to start ...

- all function calls that are part of macro-logic must be wrapped in %sysfunc

- but: why do you changed the if-blocks to %if-blocks at all? you are still in a data step

Re: Required operator not found in expression error in macro

David_Billa — Fri, 11 Dec 2020 13:24:54 GMT

How to wrap with %sysfunc?

Re: Required operator not found in expression error in macro

Kurt_Bremser — Fri, 11 Dec 2020 14:10:21 GMT

@David_Billa wrote:
How to wrap with %sysfunc?

Maxim 1: Read the Documentation. It provides the details, and lots of examples.

Re: Required operator not found in expression error in macro

hhinohar — Fri, 11 Dec 2020 14:19:15 GMT

https://communities.sas.com/t5/SAS-Programming/Filter-on-quarter-months-value-from-quarter-ending-date/m-p/704093#M215814

Re: Required operator not found in expression error in macro

SASKiwi — Sat, 12 Dec 2020 02:01:49 GMT

From what you've posted, the only macro statements required in your code are the beginning %IF statement and the finishing %END statement. Everything else can stay exactly like your first non-macro example.

%let dir1=/var/data/server/files;
%if < condition > %then %do;

/*get file details from dir1*/
data files;
fref = "DIR1";
if filename(fref,"&dir1.") = 0
then do;
  did = dopen(fref);
  if did ne 0
  then do;
    do i = 1 to dnum(did);
      name = dread(did,i);
      if upcase(scan(name,-1,".")) = "CSV" then output;
    end;
    did = dclose(did);
  end;
  rc = filename(fref);
end;
keep name;
run;

/*macro variables for digit value from each file*/
data _null_;
set files;
digits = scan(name,5,'_');
call symputx(cats("id",_n_),digits);
run;

%end;