topic Re: Overlay on Histogram in SAS Programming

Overlay on Histogram

NKormanik — Fri, 20 Nov 2020 02:44:44 GMT

Using Proc SGPannel. Please see following code:

proc sgpanel
data=sas_1.importance_long_many_variables;
panelby Indicator
/
rows=4 layout=rowlattice noheader spacing=11
;
histogram Count
/
datalabel=count
datalabelattrs=(color=navy family=arial size=8)
;
inset Indicator
/
position=right textattrs=(size=14)
;
rowaxis offsetmin=0
;
run;

Would like to overlay the histogram with three vertical lines:

Quartile 1

Mean

Quartile 3

The purpose is to compare various histograms (using same scale).

The above possibility does not appear in the documentation for sgpannel, histogram.

Any thoughts appreciated.

Thanks!

Nicholas Kormanik

Re: Overlay on Histogram

PeterClemmensen — Thu, 19 Nov 2020 13:27:06 GMT

I don't think this is possible directly. I think you have to pre-compute them.

Also, are you sure you want to plot Quintiles ? Don't you mean the first and third quartile?

Re: Overlay on Histogram

PeterClemmensen — Thu, 19 Nov 2020 13:46:19 GMT

If I am right, see if you can use this as a template. You can add labels and different coloring as you like

proc summary data = sashelp.iris nway;
   class Species;
   var SepalLength;
   output out = temp mean(SepalLength)= mean 
                     q1(SepalLength)  = q1 
                     q3(SepalLength)  = q3;
run;

data plot;
   merge sashelp.iris temp;
   by Species;
run;

proc sgpanel data = plot;
  panelby Species / rows=3 layout=rowlattice;
  histogram SepalLength;
  refline mean / axis = x;
  refline q1   / axis = x;
  refline q3   / axis = x;
run;

Re: Overlay on Histogram

NKormanik — Fri, 20 Nov 2020 02:46:55 GMT

Beautifully done, draycut. Thanks for your help.

Re: Overlay on Histogram

PeterClemmensen — Fri, 20 Nov 2020 07:00:20 GMT

@NKormanik Thank you, anytime 🙂