topic Re: IF VS Where in Datastep in SAS Programming

IF VS Where in Datastep

BrahmanandaRao — Thu, 19 Nov 2020 06:48:26 GMT

/*IF vs Where in Datastep using Aggregate Functions*/
data if;
set sashelp.class;
if Max(Age) then output;
run;

data wh;
set sashelp.class;
where Max(Age);
run;

Here I got same output ,I want max age in class dataset

Re: IF VS Where in Datastep

Kurt_Bremser — Thu, 19 Nov 2020 07:10:13 GMT

Maxim 1: Read the Documentation, here of the MAX Function:

argument

specifies a numeric constant, variable, or expression. At least one argument is required. If you use only one argument, then the value of that argument is returned.

(emphasis by me)

So in both your examples, the value of age is returned; since all observations in SASHELP.CLASS have a non-missing and non-zero age, the condition will always be true, so all observations are written to the output dataset.

If you want to retrieve the maximum of all ages in SASHELP.CLASS, you need to use the SQL summary function MAX:

proc sql;
select max(age) from sashelp.class;
quit;

Re: IF VS Where in Datastep

PeterClemmensen — Thu, 19 Nov 2020 07:08:46 GMT

The Data Step Max Function reads a list of arguments and returns the largest one. So if you have 1 argument, that argument is returnes. Ie Max(age) = Age.

What is your goal here? Do you really want a single observation in a new data set with the max value for age? Or do you just want to know what max(age) is?

Re: IF VS Where in Datastep

yabwon — Thu, 19 Nov 2020 07:57:58 GMT

If you want do get it with data step you can do it with help of DoW-loop:

data want1;
  do until(eof);
    set sashelp.class end=eof;
    max = max(max,Age);
  end;

  do until(end);
    set sashelp.class end=end;
    if max = Age then output;
  end;
run;

But I would use SQL for this task:

proc sql;
  create table want2 as
  select * 
  from sashelp.class
  having age = max(age)
  ;
quit;

All the best

Bart

Re: IF VS Where in Datastep

LeonidBatkhan — Thu, 19 Nov 2020 14:53:45 GMT

Hi Anandkvn,

Function max() works within single observation.

If you want get max of a variable across the observations you may use methods suggested by KurtBremse and yabwon .

Another way of getting max(AGE) is this:

proc sort data=sashelp.class out=work.class;
   by descending AGE;
run;

data work.maxage;
   set work.class (obs=1);
   put 'max(AGE)=' AGE;
run;

Hope this helps.