topic Re: Create an empty dataset with variables and no unintialized issues in log in SAS Programming

Create an empty dataset with variables and no unintialized issues in log

Anonymity — Fri, 06 Nov 2020 13:27:40 GMT

I need to create an empty dataset but without the uninitialized issue that shows in the log.

I have tried the following

data SHELL;
format FirstName LastName $200.;
stop;
run;

and this

data SHELL;
length FirstName LastName $200;
stop;
run;

Unfortunately I am still getting uninitialized in my log.

I would like to try to avoid this as I would be doing this for about +- 30 variables every time.

data SHELL;
length FirstName LastName $200;

FirstName = "";

LastName = "";

run;

Help with this would be appreciated.

Re: Create an empty dataset with variables and no unintialized issues in log

PaigeMiller — Fri, 06 Nov 2020 13:32:18 GMT

The log message about uninitialized variables is expected in the case where you have uninitialized variables, and is not a bad thing in this case in my opinion. So I don't have a problem with the log message, and I wouldn't spend time and effort to fix it (if a fix is possible).

Re: Create an empty dataset with variables and no unintialized issues in log

yabwon — Fri, 06 Nov 2020 13:34:12 GMT

data SHELL;
    length FirstName LastName $ 200;
    call missing(of _ALL_);
    stop;
run;

Bart

Re: Create an empty dataset with variables and no unintialized issues in log

FreelanceReinh — Fri, 06 Nov 2020 15:07:20 GMT

Hi @Anonymity,

In practice, I would also use the DATA step approach with CALL MISSING because of the familiar syntax. Other options include:

PROC SQL

proc sql;
create table SHELL
(FirstName char(200), LastName char(200));
quit;

Temporarily suppress the unwanted note in the log (and then use a DATA step without the need for CALL MISSING):
```
options varinitchk=nonote;
```
and reset the option to note (or whatever the previous setting was) afterwards.

Use one or more arrays:

data SHELL;
array x[*] $200 FirstName LastName;
stop;
run;

Re: Create an empty dataset with variables and no unintialized issues in log

Tom — Fri, 06 Nov 2020 15:10:56 GMT

You can use CALL MISSING(of _all_) to initialize the variables.

You can also use an array definition as SAS doesn't issue the note for variables that are in arrays. But that requires that you need to know if you have both numeric and character variables since all variables in a single array must be of the same type.

PS Use the LENGTH statement to define the type/length of the variables. Use a FORMAT statement only if you actually need to attach a format to the variables. Your example variables do not need formats attached to them.