topic Re: Leading 0 in string where there are also non-numeric values in SAS Programming

Leading 0 in string where there are also non-numeric values

raivester — Thu, 29 Oct 2020 15:36:46 GMT

Hello--

I recently received a data set with Var1 values: '1' '2' '3' '4' '5' '10' '11' '12' '13' '14' '15' 'unknown.' This variable is obviously character, but I need leading 0s on the digits that are less than 10. Is there an elegant way to do this?

Thanks

Re: Leading 0 in string where there are also non-numeric values

Reeza — Thu, 29 Oct 2020 15:39:54 GMT

Want = put(input(var1, 8.), z2.);

Or convert it to a number and display with Z2 format.

want = input(var1, 8.);
format want Z2.;

Re: Leading 0 in string where there are also non-numeric values

raivester — Thu, 29 Oct 2020 15:42:43 GMT

will this work if one of the variable values is the character string "unknown"?

Re: Leading 0 in string where there are also non-numeric values

FreelanceReinh — Thu, 29 Oct 2020 15:44:15 GMT

Hello @raivester,

I'd suggest this:

data want;
set have;
if lengthn(var1)=1 then var1='0'||var1;
run;

(I use LENGTHN, not LENGTH, because missing values should not be replaced by zeros.)

Re: Leading 0 in string where there are also non-numeric values

Reeza — Thu, 29 Oct 2020 15:47:48 GMT

No, but you could add an IF to conditionally execute the conversion or change unknown to show as missing or a SAS special missing value.

Re: Leading 0 in string where there are also non-numeric values

raivester — Thu, 29 Oct 2020 15:51:35 GMT

Ahh! Good thinking. Thanks for the help

Re: Leading 0 in string where there are also non-numeric values

Kurt_Bremser — Thu, 29 Oct 2020 15:52:19 GMT

Try this:

data have;
input var1 $;
datalines;
1
2
3
4
5
6
11
12
13
14
15
unknown
;

data want;
set have;
if anyalpha(var1) = 0
then var1 = put(input(var1,best.),z2. -l);
run;

Re: Leading 0 in string where there are also non-numeric values

ballardw — Thu, 29 Oct 2020 16:30:21 GMT

Do you expect to need to do arithmetic with these values? Or model with the numeric value ?

If so, then read them as numeric so the unknown are missing and if you need a leading zero use a Z2. format.