topic Re: set data sets and create new variable with source name in SAS Programming

set data sets and create new variable with source name

Ronein — Tue, 27 Oct 2020 12:42:46 GMT

hello

I am using set statement to concatenate data sets.

I want to create a new column with information of source data set (value will be from letter 4 till letter 7 in data set name. for example: if source data set is ABC1912 then value will be 1912 and so on


Data ABC1912;
input x;
cards;
1
2
;
run;
Data ABC2001;
input x;
cards;
11
22
;
run;
Data ABC2002;
input x;
cards;
13
22
;
run;
Data ABC2003;
input x;
cards;
1
23
;
run;
Data final;
set ABC1912 ABC2001  ABC2002  ABC2003;
/*I want to create a new variable that will get value from the source data set name:
If the observation from data set ABC1912 then will get value 1912
If the observation from data set ABC2001 then will get value 2001
If the observation from data set ABC2002 then will get value 2002
If the observation from data set ABC2003 then will get value 2003*/
Run;

Re: set data sets and create new variable with source name

PeterClemmensen — Tue, 27 Oct 2020 12:47:31 GMT

Try this

Data final;
    set ABC1912 
        ABC2001  
        ABC2002  
        ABC2003 indsname=ds;
    newvar = compress(scan(ds,2,'.'),, 'kd');
Run;

Re: set data sets and create new variable with source name

PaigeMiller — Tue, 27 Oct 2020 12:49:31 GMT

Data final;
set ABC1912 ABC2001  ABC2002  ABC2003 indsname=indsname;
source=substr(scan(indsname,2),4);
Run;

Re: set data sets and create new variable with source name

Ronein — Wed, 28 Oct 2020 05:59:46 GMT

Great!

Now all is clear.

Re: set data sets and create new variable with source name

Ronein — Tue, 27 Oct 2020 14:43:05 GMT

Can you please explain why you used number 2 ?

What is ds?

Does 'kd' means to take only digits?

compress(scan(ds,2,'.'),, 'kd');

Re: set data sets and create new variable with source name

Kurt_Bremser — Tue, 27 Oct 2020 15:11:42 GMT

The dataset name as returned into the INDSNAME= variable contains the library and dataset name, so the SCAN function extracts the dataset name. The COMPRESS then extracts the part you are interested in, as you suspected (see section "modifier").