topic Re: Remove Words in SAS Programming

Remove Words

luvscandy27 — Tue, 27 Oct 2020 00:12:19 GMT

Please forgive me, I have been trying to figure this out for sometime now and I have read the various solutions related to my question, in this forum, but I am still unable to come up with a solution.

My problem is I have a dataset like below (also attached) with hundreds of observations.

Ft.Belvoir, VA

Annapolis NHC, MD

Camp Pendleton NH, CA

What I would like to do is keep just the name part and add the word location in the front. I would like to end up with:

Location Ft. Belvoir

Location Annapolis

Location Camp Pendleton

Could someone assist me with this please?

Re: Remove Words

CurtisMackWSIPP — Tue, 27 Oct 2020 00:33:17 GMT

This is made difficult because you have no clear definition of what the "name part" is.

In this example I assumed you wanted every up to the first occurrence of "NH" or the first comma.

data have;
  infile datalines dlm="-";
  length city $ 40;
  input city $;
datalines;
Ft.Belvoir, VA
Annapolis NHC, MD 
Camp Pendleton NH, CA 
;
run;


data want(drop=place);
  set have;
  if index(city,"NH") then place = substr(city,1,index(city,"NH")-1);
  else place = scan(city,1,", ");
  location = catx(" ","Location",place);
run;

Re: Remove Words

ChrisNZ — Tue, 27 Oct 2020 04:33:02 GMT

This keeps the string until a comma or 2 uppercase letters are encountered:

data HAVE;
  input CITY :& $40.;
cards;
Ft.Belvoir, VA
Annapolis NHC, MD 
Camp Pendleton NH, CA 
run;

data WANT;
  set HAVE;
  LOCATION = prxchange('s/(.*?)(,|([A-Z]{2})).*/Location \1/',1,CITY);
run;

CITY	LOCATION
Ft.Belvoir, VA	Location Ft.Belvoir
Annapolis NHC, MD	Location Annapolis
Camp Pendleton NH, CA	Location Camp Pendleton