topic Re: Help to remain only distinct values in a row in SAS Programming

Help to remain only distinct values in a row

Stu_J — Sat, 24 Oct 2020 02:15:53 GMT

hello,

I would like to get only the distinct values for a new variable.

for example,

ID var

1 AABI

2 TIBBC

3 TTIBTIC

so I would like to have a the new variable as output below:

ID var var_new

1 AABI ABI

2 TIBBC TIBC

3 TTIBTIC TIBC

Re: Help to remain only distinct values in a row

mkeintz — Sat, 24 Oct 2020 02:42:30 GMT

What about ABAI? I has 2 A's, but they are not contiguous.

Re: Help to remain only distinct values in a row

Stu_J — Sat, 24 Oct 2020 02:58:06 GMT

Only keeping the distinct values, so ABAI new variable will be ABI

Re: Help to remain only distinct values in a row

novinosrin — Sat, 24 Oct 2020 03:12:50 GMT


data have;
input ID var $;
cards;
1 AABI
2 TIBBC
3 TTIBTIC
;

data want ;
 if _n_=1 then do;
   dcl hash H () ;
   h.definekey  ("k") ;
   h.definedone () ;
 end;
 set have;
 length var_new $30;
 do _n_=1 to lengthn(var);
  k= char(var,_n_);
  if h.check()=0 then continue;
  var_new=cats(var_new,k);
  h.add();
 end;
 h.clear();
 drop k;
run;

Re: Help to remain only distinct values in a row

Stu_J — Sat, 24 Oct 2020 04:20:18 GMT

thanks, I don't have much knowledge with hash object. that's very nice.

Re: Help to remain only distinct values in a row

Ksharp — Sat, 24 Oct 2020 11:56:20 GMT


data have;
input ID var $;
cards;
1 AABI
2 TIBBC
3 TTIBTIC
;
data want;
 set have;
 array x{100} $ 1 _temporary_;
 n=0;call missing(of x{*});
 do i=1 to length(var);
   temp=char(var,i);
   if temp not in x then do;n+1;x{n}=temp;end;
 end;
 want=cats(of x{*});
 drop n i temp;
run;