topic Re: Optimize CATX Function in SAS Programming

Optimize CATX Function

Longbottom_88 — Thu, 22 Oct 2020 11:47:07 GMT

Dear SAS users,

Could you please help me how to optimize or to paraphrase this code into more elegant. I make some code using CATX function. The goal is i want to have three different option in result variable.

Thanks

Waldorf

DATA test1;
SET table_005_test_dec;
KEEP aval lbnrind lbclsig test_dec;
RUN;

DATA test2;
SET test1;
IF NOT MISSING(aval) AND CMISS(lbnrind,lbclsig) = 0 THEN DO;
result = CATX(' ', PUT(ROUND(aval, test_dec), best.), '('!!STRIP(SUBSTR(lbnrind, 1, 1))!!')', '('!!STRIP(lbclsig)!!')');
END;
IF NOT MISSING(aval) AND CMISS(lbclsig) = 0 AND CMISS(lbnrind) = 1 THEN DO;
result = CATX(' ', PUT(ROUND(aval, test_dec), best.), '('!!STRIP(lbclsig)!!')');
END;
IF NOT MISSING(aval) AND CMISS(lbclsig) = 1 AND CMISS(lbnrind) = 0 THEN DO;
result = CATX(' ', PUT(ROUND(aval, test_dec), best.), '('!!STRIP(SUBSTR(lbnrind, 1, 1))!!')');
END;
RUN;

Re: Optimize CATX Function

Kurt_Bremser — Thu, 22 Oct 2020 12:04:51 GMT

Pull the first condition and its part of the CATX's out into a separate DO/END block:

data test2;
set test1;
if not missing(aval)
then do;
  result = put(round(aval,test_dec),best.);
  if lbnrind ne "" and lbclsig ne ""
  then result = catx(' ',
    result,
    '('!!strip(substr(lbnrind,1,1))!!')',
    '('!!strip(lbclsig)!!')'
  );
  if lbclsig ne "" and lbnrind = ""
  then result = catx(' ', result, '('!!strip(lbclsig)!!')');
  if lbclsig = "" and lbnrind ne ""
  then result = catx(' ',result,'('!!strip(substr(lbnrind,1,1))!!')');
end;
run;

I also replaced the CMISS functions with direct comparisons, as those variables can be assumed to be character anyway; direct comparisons are faster than function calls.

Re: Optimize CATX Function

ballardw — Thu, 22 Oct 2020 15:03:57 GMT

If you are using the !! in this to concatenate you might consider nesting a cats call

'('!!STRIP(SUBSTR(lbnrind, 1, 1))!!')'

cats ( '(',SUBSTR(lbnrind, 1, 1),')' )

may not "optimize" but is less typing and a bit easier to follow. Plus with CATS you shouldn't need the STRIP function call. You can nest the various CAT functions inside each other just like using the SUBSTR or other functions.

Re: Optimize CATX Function

Longbottom_88 — Mon, 26 Oct 2020 07:49:35 GMT

Hi Kurt, Thanks for the answer. Cheers

Re: Optimize CATX Function

Longbottom_88 — Mon, 26 Oct 2020 07:50:05 GMT

Hi Ballardw, thanks for the answer. Cheers