topic Macro parameter of previous month with numeric sas date value in SAS Programming

Macro parameter of previous month with numeric sas date value

Ronein — Wed, 21 Oct 2020 11:31:08 GMT

Hello

I want to ask a question regarding creating a sas macro parameter.

User define current month (Let's say Sep 2020) with YYMM format.

There are 2 tasks:

1-Create macro parameter of start of previews month(number that represent sas date).

2-Create macro parameter of previews month in YYMM structure (Result:1908)

I have a problem to perform the 2nd task

thank you

Mer

Re: Macro parameter of previous month with numeric sas date value

Ronein — Wed, 21 Oct 2020 11:28:13 GMT


%let Cur_Mon_YYMM=1909;/*YYMM structure*/

%let Cur_Mon_date=%sysfunc(inputn(&Cur_Mon_YYMM.,yymmn4.));
/*SAS date:number of days since 1.1.1960*/

%put &Cur_Mon_date;

%let Prev_mon=%sysfunc(intnx(month,&Cur_Mon_date.,-1));
/*SAS date:number of days since 1.1.1960*/
%put &Prev_mon;

%let Prev_mon_YYMM=?????

Re: Macro parameter of previous month with numeric sas date value

Kurt_Bremser — Wed, 21 Oct 2020 11:37:38 GMT

For the 2nd:

%let in=2009;
%let begin_last_month=%sysfunc(intnx(month,%sysfunc(inputn(20&in.01,yymmdd8.)),-1,b));

data _null_;
x=&begin_last_month;
put x yymmdd10.;
run;

Re: Macro parameter of previous month with numeric sas date value

Ronein — Wed, 21 Oct 2020 12:24:46 GMT

Thank you.

The desired outcome is 1908 ( by YYMM structrure).

In the code that you sent I get sas date value and not 1908

Re: Macro parameter of previous month with numeric sas date value

PaigeMiller — Wed, 21 Oct 2020 12:28:00 GMT

Then you can assign it the proper format.

Re: Macro parameter of previous month with numeric sas date value

Kurt_Bremser — Wed, 21 Oct 2020 13:03:31 GMT

@Ronein wrote:

Thank you.

The desired outcome is 1908 ( by YYMM structrure).

In the code that you sent I get sas date value and not 1908

Dead simple:

%let begin_last_month=%sysfunc(intnx(month,%sysfunc(inputn(20&in.01,yymmdd8.)),-1,b),yymmn4.);

%put &begin_last_month.;

Re: Macro parameter of previous month with numeric sas date value

Kurt_Bremser — Wed, 21 Oct 2020 13:15:29 GMT

PS your subject line asked specifically for a SAS date value.

Re: Macro parameter of previous month with numeric sas date value

Ronein — Thu, 22 Oct 2020 08:32:27 GMT

Thank you All,

I wrote a summary based on the posts.

%let Cur_YYMM=1909;
%let lastMon_YYMM=%sysfunc(intnx(month,%sysfunc(inputn(&Cur_YYMM,yymmn4.)),-1),yymmn4.);
%put &lastMon_YYMM.;
/*1908*/

%let StartOflastMon_date=%sysfunc(intnx(month,%sysfunc(inputn(&Cur_YYMM,yymmn4.)),-1,b));
%put &StartOflastMon_date.;
/*21762 that represent #days from 1.1.1960 til 01Aug2020*/

%let EndOflastMon_date=%sysfunc(intnx(month,%sysfunc(inputn(&Cur_YYMM,yymmn4.)),-1,E));
%put &EndOflastMon_date.;
/*21792 that represent #days from 1.1.1960 til 31Aug2020*/