topic Re: Dummy variables for multiple categories in a single field in SAS Programming

Dummy variables for multiple categories in a single field

Jedrek369 — Tue, 20 Oct 2020 20:16:58 GMT

Hello,

This is my original table:

col

a; b; c

b; b; d

And I want to convert it to:

col	is_a	is_b	is_c	is_d
a; b; c	1	1	1	0
b; b; d	0	1	0	1
d	0	0	0	1

Any help would be much appreciated!

Jedrek

Re: Dummy variables for multiple categories in a single field

Reeza — Tue, 20 Oct 2020 20:53:37 GMT

Is it just the 4 values? Or does these need to be extended and this is a simplified version of your problem?

Re: Dummy variables for multiple categories in a single field

PGStats — Tue, 20 Oct 2020 21:22:51 GMT

The straitforward way:

data have;
input col &:$20.;
datalines4;
a; b; c
b; b; d
d
;;;;

data list;
set have;
obs = _n_;
value = 1;
do i = 1 to countw(col,";");
    w = strip(scan(col, i, ";"));
    output;
    end;
drop i;
run;

proc sort data=list nodupkey; by obs w; run;

proc transpose data=list out=table(drop=_name_ obs) prefix=is_;
id w;
var value;
by obs col;
run;

proc stdize data=table reponly missing=0 out=want;
var is_:;
run;

Re: Dummy variables for multiple categories in a single field

Jedrek369 — Wed, 21 Oct 2020 06:35:40 GMT

Thank you very much! Have a good day.