topic Re: How to get middle name from a string? in SAS Programming

How to get middle name from a string?

shravanisreeyan — Sun, 18 Oct 2020 18:24:06 GMT

data have;

input a$30.;

cards;

st john school

st xavier school

st little flower school

;

run;

data want

john

xavier

little flower

Can i get code for this?many thanks

Re: How to get middle name from a string?

novinosrin — Sun, 18 Oct 2020 19:46:42 GMT


data have;

input a$30. ;

cards;
st john school
st xavier school
st little flower school
;

run;

data want;
 set have;
 length need $100;
 do _n_=2 to countw(a,' ')-1;
  need=catx(' ',need,scan(a,_n_));
 end;
run;

Re: How to get middle name from a string?

novinosrin — Sun, 18 Oct 2020 20:03:56 GMT



data have;

input a$30. ;

cards;
st john school
st xavier school
st little flower school
;

run;

data want;
 set have;
 length need $100;
 _n_=anyspace(strip(a));
 need=substr(a,_n_,anyspace(strip(a),-99)-_n_);
run;

Re: How to get middle name from a string?

PaigeMiller — Mon, 19 Oct 2020 10:25:27 GMT

Hello, @shravanisreeyan, maybe you could please provide more realistic example, so we can solve the real problem?

What do you want to have as a result if a name does not have a middle name? Does that ever happen in your data?

What do you want as a result if a last name has two "words", such as Stan Van Gundy, in this case Van Gundy is the last name, and no middle name. Does that ever happen in your data?

Parsing names can require some pretty complicated rules, if you are working with real world data.

Re: How to get middle name from a string?

Ksharp — Mon, 19 Oct 2020 13:37:24 GMT

data have;
input a$30. ;
cards;
st john school
st xavier school
st little flower school
;
run;

data want;
 set have;
 want=prxchange('s/^\w+|\w+$//',-1,strip(a));
run;