topic Re: conditional ods rtf text= in SAS Programming

conditional ods rtf text=

cminard — Wed, 14 Oct 2020 20:29:40 GMT

Why doesn't this work?

/*******************/

data temp;
do id = 1 to 10;
x=ranuni(134);
y=ranuni(135);
output;
end;
run;

ods rtf file="<your directory>\test.rtf";
%macro m1 ();
%let mytitle=This is my title;
%let xvalue=;
data _null_;
set temp;
call symputx ('xvalue',x);
run;

%let yvalue=999;
%if (&yvalue ne ) %then ods rtf text="Xvalue is %sysfunc(round(&xvalue,.01)).";
title "&mytitle";
proc sgplot data=temp;
scatter x=x y=y;
run;
title ;
%mend m1;
%m1;

ods rtf close;

/*********************/

When I execute this code, I get the following error message:

TIA

Re: conditional ods rtf text=

CurtisMackWSIPP — Wed, 14 Oct 2020 20:36:45 GMT

Use a "DO; END" block on that if statement.

data temp;
do id = 1 to 10;
x=ranuni(134);
y=ranuni(135);
output;
end;
run;

ods rtf file="<your directory>\test.rtf";
%macro m1 ();
%let mytitle=This is my title;
%let xvalue=;
data _null_;
set temp;
call symputx ('xvalue',x);
run;

%let yvalue=999;
%if (&yvalue ne ) %then %do;
ods rtf text="Xvalue is %sysfunc(round(&xvalue,.01)).";
%end;
title "&mytitle";
proc sgplot data=temp;
scatter x=x y=y;
run;
title ;
%mend m1;
%m1;

ods rtf close;

Re: conditional ods rtf text=

novinosrin — Wed, 14 Oct 2020 20:45:11 GMT

Hi @cminard You are missing a semi colon to end the ODS RTF for the reason the semi colon present acts as step boundary rather for the %IF macro statement. You would need another semi colon, however the inner semi colon would have to be quoted aka masked to be treated as text using %STR funciton. So-


%if (&yvalue ne ) %then ods rtf text="Xvalue is %sysfunc(round(&xvalue,.01))."%str(;) ;

Re: conditional ods rtf text=

ballardw — Wed, 14 Oct 2020 21:07:05 GMT

I would recommend moving all macro definitions outside of an ODS destination block (ODS destination/ ods destination close ). Partially it makes code easier to follow but may also address your spefic issue. Additionally to test just the output part you don't end up recompiling the macro multiple times (efficiency) and may be easier test.

Dummy code to illustrate what I mean.

%macro m1();
<code in macro>
%mend m1;

ods rtf file ="path\file.rtf";

%m1;

ods rtf close;

Debug macro behavior by setting OPTIONS MPRINT; before execution. The log will usually have more details of what the macro compiler actually generated.

Use Options NOMPRINT; to turn of the details.

Re: conditional ods rtf text=

ChrisNZ — Wed, 14 Oct 2020 22:56:21 GMT

The macro code is in red:

%if (&yvalue ne ) %then ods rtf text="Xvalue is %sysfunc(round(&xvalue,.01))." ;

As you can see you haven't closed the ODS statement.

You can add a %do block as shown, or another proper way would be:

%if (&yvalue ne ) %then ods rtf text="Xvalue is %sysfunc(round(&xvalue,.01))."%str(;) ;

or just as good (and you'll get a semicolon even if the test fails):

%if (&yvalue ne ) %then ods rtf text="Xvalue is %sysfunc(round(&xvalue,.01)). ; ;

Re: conditional ods rtf text=

cminard — Wed, 14 Oct 2020 23:12:41 GMT

Thank you all. Yes, I am missing a semi-colon to close that %if statement. Thanks for all other suggestions as well.

Re: conditional ods rtf text=

cminard — Wed, 14 Oct 2020 23:16:57 GMT

Intended to mark this one as the solution.

Re: conditional ods rtf text=

ChrisNZ — Wed, 14 Oct 2020 23:50:00 GMT

You can change