topic macro and proc summary question in SAS Programming

macro and proc summary question

jdub — Thu, 13 Dec 2012 23:42:08 GMT

Howdy

I have a very basic macro I am trying use with proc summary. I can see the problem but cannot figure out a solution. Here is my code:

%macro supersum;

proc summary

data=occ_haves;

by cluster;

%do i=1 %to 12;

var base&i;

output out=occ_category sum=sbase&i;

%end;

run;

%mend supersum;

%supersum

I would like the loop to create one data set named occ_category containing 12 summation variables ranging from sbase1 to sbase12. My code is creating a separate data set per summation variable created. So, I get errors that say:

ERROR: Data set WORK.OCC_CATEGORY is already open for output

What I do not know is how or if I can create all 12 variables in the same data set.

Any help would be appreciated.

Re: macro and proc summary question

art297 — Fri, 14 Dec 2012 00:01:23 GMT

I don't think you need a macro. Does the following approximate what you want to accomplish?:

/*create some test data*/

data occ_haves;

set sashelp.class (rename=(sex=cluster));

array sbase(14);

do i=1 to 14;

sbase(i)=height;

end;

run;

proc summary

data=occ_haves nway;

class cluster;

var sbase1-sbase12;

output out=occ_category sum= /autoname;

run;

Re: macro and proc summary question

jdub — Fri, 14 Dec 2012 00:37:27 GMT

That is some handy code. I am getting used to macros and think i unnecessarily use them at times. Why did you use a 'class cluster' in the summary versus a 'by cluster'? The /autoname is very cool as well.

thanks

Re: macro and proc summary question

art297 — Fri, 14 Dec 2012 00:39:27 GMT

When you use class, as opposed to by, you don't have to presort the dataset.

Re: macro and proc summary question

jdub — Fri, 14 Dec 2012 00:46:14 GMT

oh man, I feel so slow to have not known this but also your answer is a total score!

Re: macro and proc summary question

art297 — Fri, 14 Dec 2012 01:33:50 GMT

Don't feel slow! I've likely been using SAS for a bit longer than you have!