topic Re: Remove 'Master_Names' in the text? in SAS Programming

Remove 'Master_Names' in the text?

ybz12003 — Wed, 30 Sep 2020 18:52:34 GMT

Hello, experts,

I have a sample dataset 'Have.' I would like to remove all the names shown in the dataset 'Maste_Name.' The final result is shown in the dataset 'Want.' Please help me to approach it. Thank you.

data Master_Name;
      infile datalines dsd;
  input  Name : $50. ;
datalines;
	uairway,
	uapnea,
	ugastro,
	ugerd,
	uendo,
	uallergy
	;
run;


data Have;
      infile datalines delimiter='/';
  input Disease : $300.  ;
datalines;
	UGASTRO, UGERD, UALLERGY /
	UAIRWAY, CONGENITAL ATRESIA OF ESOPHA, UGASTRO /
	ECZEMA
;
run;

data Want;
      infile datalines delimiter='/';Re
  input Disease : $300.  ;
datalines;
	  /
	CONGENITAL ATRESIA OF ESOPHA /
	ECZEMA
;
run;

Re: Remove 'Master_Names' in the text?

jimbarbour — Wed, 30 Sep 2020 19:17:23 GMT

Have you tried using the Tranwrd function? If the replacement value is '', then that should remove the text that you don't want. You might want to run a COMPBL thereafter to compress any multiple spaces.

Jim

Re: Remove 'Master_Names' in the text?

jimbarbour — Wed, 30 Sep 2020 20:17:03 GMT

For example, the following:

data Master_Name;
      infile datalines dsd;
  input  Name : $50. ;
datalines;
uairway,
uapnea,
ugastro,
ugerd,
uendo,
uallergy
;
run;


data Have;
      infile datalines delimiter='/';
  input Disease : $300.  ;
datalines;
UGASTRO, UGERD, UALLERGY /
UAIRWAY, CONGENITAL ATRESIA OF ESOPHA, UGASTRO /
ECZEMA
;
run;

DATA	_NULL_;
	CALL	SYMPUTX('Names_Cnt', Names_Cnt, 'G');
	STOP;
	SET	Master_Name	NOBS	=	Names_Cnt;
RUN;

DATA	Want;
	DROP	Name;
	DROP	_:;

	ARRAY	Names	[&Names_Cnt]	$50	_TEMPORARY_;
	SET	Have;

	IF	_N_	=	1	THEN
		DO;
			DO	WHILE	(NOT	End_Of_Master);
				SET	Master_Name
					END		=	End_of_Master
					;
				_i			+	1;
				Names[_i]	=	Name;
			END;
		END;

	DO	_i		=	1	TO	&Names_Cnt;
		Disease	=	COMPBL(TRANWRD(UPCASE(Disease), CATS(UPCASE(Names[_i]), ','), ''));
		IF	SUBSTR(Disease, LENGTH(TRIM(Disease)), 1)	=	','	THEN
			Disease	=	SUBSTR(Disease, 1, LENGTH(STRIP(Disease)) - 1);
		Disease	=	COMPBL(TRANWRD(UPCASE(Disease), STRIP(UPCASE(Names[_i])), ''));
		IF	SUBSTR(Disease, LENGTH(TRIM(Disease)), 1)	=	','	THEN
			Disease	=	SUBSTR(Disease, 1, LENGTH(STRIP(Disease)) - 1);
	END;

	IF	NOT	INDEX(Disease, '/')	THEN
		Disease	=	CAT(STRIP(Disease), ' /');		
RUN;

Which yields:

Jim

Re: Remove 'Master_Names' in the text?

Ksharp — Thu, 01 Oct 2020 12:59:17 GMT

data Master_Name;
      infile datalines dsd;
  input  Name : $50. ;
datalines;
uairway,
uapnea,
ugastro,
ugerd,
uendo,
uallergy
;
run;


data Have;
      infile datalines delimiter='/';
  input Disease : $300.  ;
datalines;
UGASTRO, UGERD, UALLERGY /
UAIRWAY, CONGENITAL ATRESIA OF ESOPHA, UGASTRO /
ECZEMA
;
run;


options noquotelenmax;
proc sql noprint;
select name into : names separated by '|' from master_name;
quit;

%put &names;

data want;
 set have;
 want=tranwrd(prxchange("s/\b&names\b/ /i",-1,disease),' ,',' ');
 run;

Re: Remove 'Master_Names' in the text?

ybz12003 — Thu, 01 Oct 2020 13:28:33 GMT

Wow, this is SUPER!!

What is the 's' in front of '/' used for? And what is '-1' for?

Re: Remove 'Master_Names' in the text?

Ksharp — Thu, 01 Oct 2020 13:36:07 GMT

What is the 's' in front of '/' used for?
s stands for substitute or replace .

And what is '-1' for?
-1 means replace as many times as it could be .

Re: Remove 'Master_Names' in the text?

ybz12003 — Thu, 01 Oct 2020 13:40:08 GMT

Thanks much!