topic Re: Simplify the coding - Macro? Do Loop? in SAS Programming

Simplify the coding - Macro? Do Loop?

ybz12003 — Tue, 29 Sep 2020 16:14:29 GMT

Hello,

Is there a way to simplify the codes below. I have around 15 lines of Prxmatch. I list a few of them below, thanks.

data want;
   set have;
    if prxmatch('/uairway/i',uothersp) then uairway=1; 
	if prxmatch('/uapnea/i',uothersp) then uapnea=1;
	if prxmatch('/ugastro/i',uothersp) then ugastro=1;
	if prxmatch('/ugerd/i',uothersp) then ugerd=1;
	if prxmatch('/uendo/i',uothersp) then uendo=1;
	if prxmatch('/uallergy/i',uothersp) then uallergy=1;
	if prxmatch('/uprem/i',uothersp) then uprem=1;
	if prxmatch('/ugestage/i',uothersp) then ugestage=1;

run;

Re: Simplify the coding - Macro? Do Loop?

Reeza — Tue, 29 Sep 2020 16:22:23 GMT

Have you tried an array?

Re: Simplify the coding - Macro? Do Loop?

PGStats — Tue, 29 Sep 2020 19:43:05 GMT

Can there be many matches for the same string?

Re: Simplify the coding - Macro? Do Loop?

ChrisNZ — Wed, 30 Sep 2020 01:46:25 GMT

Not a simplification (I don't think you can in a meaningful way), but a performance improvement: The find() function is a lot less expensive than the prxmatch() function.

Also this syntax might be slightly more compact:

UAIRWAY = find(UOTHERSP, 'uairway', 'i') > 0 ;

Re: Simplify the coding - Macro? Do Loop?

ChrisNZ — Wed, 30 Sep 2020 03:57:15 GMT

If you really want to remove the tests, you can do something like this:

%let strings=UAIRWAY UGASTRO;
%macro loop;
  %local i;
  %do i=1 %to %sysfunc(countw(&strings));
    %scan(&strings,&i) = find(UOTHERSP, "%scan(&strings,&i)", 'i') > 0 ; 
  %end;
%mend;
%loop;

You removed 15-8=7 lines of code, but it's a lot less legible now. Not worth it imho.

Re: Simplify the coding - Macro? Do Loop?

gamotte — Wed, 30 Sep 2020 09:22:03 GMT

Hello,

Following @Reeza advice of using arrays :

data want;
    set have;
	array vars uairway uapnea ugastro ugerd uendo uallergy uprem ugestage;

    do over vars;
        if find(uothersp,vname(vars),"i") then vars=1;
    end;
run;

Re: Simplify the coding - Macro? Do Loop?

ybz12003 — Wed, 30 Sep 2020 18:31:12 GMT

Thank you so much, ChrisNZ and Gamotte. Both programs work!