topic Re: sas code in SAS Programming

sas code

mpangli — Fri, 25 Sep 2020 08:25:38 GMT

I want to be able to calculate the percentage change between the top value then the value below (CUML_VOL) and keep moving down a row and doing the same

so for the first line I want to be able to calculate the difference between 66040.047 and 65895.855 as a starting point.

i want the result to be displayed on the top row (but as you can see it stores it on the 2nd row and so on)

and to keep working down until it gets to a new UC_POD_EXT

so in this case it would restart the calculation when it gets to UC_POD_EXT = 1346502

this is the code I tried:

data alldata;
set alldata;
retain percent_change;
by uc_pod_ext;
if last.uc_pod_ext then percent_change=0;
else
percent_change = lag(cuml_vol) - cuml_vol ;
run;

Re: sas code

Kurt_Bremser — Fri, 25 Sep 2020 10:02:28 GMT

This:

data alldata;
set alldata;

is a bad idea; if something untoward happens in the DATA step, you have destroyed your dataset.

Do a "look-ahead":

data want;
merge
  alldata
  alldata (
    firstobs=2
    keep=uc_pod_ext cuml_vol
    rename=(uc_pod_ext=_uc cuml_vol=_cuml)
  )
;
if uc_pod_ext = _uc
then percent_change = _cuml - cuml_vol;
else percent_change = 0;
drop _:;
run;

Untested; for tested code, supply example data in usable form, namely a data step with datalines; do not post pictures, and post your code into a code box opened with the "little running man" button right next to the one indicated:

Re: sas code

mpangli — Fri, 25 Sep 2020 09:38:23 GMT

thank you so much - it worked 🙂